.section	.mdebug.abi32
.previous
.set    noreorder
.cfi_sections	.debug_frame
.abicalls
#ifdef __PIC__
	.option	pic2
#else
	.option	pic0
#endif
.text

.global __cp_begin
.hidden __cp_begin
.type   __cp_begin,@function
.global __cp_end
.hidden __cp_end
.type   __cp_end,@function
.global __cp_cancel
.hidden __cp_cancel
.type   __cp_cancel,@function
.hidden __cancel	/* long __cancel() in src/thread/pthread_cancel.c */
.global __syscall_cp_asm
.hidden __syscall_cp_asm
.type   __syscall_cp_asm,@function

/*
long __syscall_cp_asm(
	volatile int *cancel,
	syscall_arg_t nr,
	syscall_arg_t u,
	syscall_arg_t v,
	syscall_arg_t w,
	syscall_arg_t x,
	syscall_arg_t y,
	syscall_arg_t z)
*/

	.ent	__syscall_cp_asm
	.frame	$sp, 32, $ra
	.mask	0x00000000, 0
	.fmask	0x00000000, 0
	.cfi_startproc
	.cfi_return_column $ra
__syscall_cp_asm:
	subu    $sp, $sp, 32
	.cfi_adjust_cfa_offset 32
__cp_begin:
	lw      $4, 0($4)
	bne     $4, $0, __cp_cancel
	move    $2, $5
	move    $4, $6
	move    $5, $7
	lw      $6, 48($sp)
	lw      $7, 52($sp)
	lw      $8, 56($sp)
	lw      $9, 60($sp)
	lw      $10,64($sp)
	sw      $8, 16($sp)
	sw      $9, 20($sp)
	sw      $10,24($sp)
	sw      $2, 28($sp)
	lw      $2, 28($sp)
	syscall
__cp_end:
	beq     $7, $0, 1f
	addu    $sp, $sp, 32
	.cfi_adjust_cfa_offset -32
	subu    $2, $0, $2
1:	jr      $ra
	nop

__cp_cancel:
	move    $2, $ra
	.cfi_register $ra, $2
	bal     1f
	addu    $sp, $sp, 32
	.cfi_adjust_cfa_offset -32
	.gpword .
	.gpword __cancel
1:	lw      $3, ($ra)
	subu    $3, $ra, $3
	lw      $25, 4($ra)
	addu    $25, $25, $3
	jr      $25
	move    $ra, $2
	.cfi_restore $ra
#ifdef __ELF__
	.size __syscall_cp_asm,.-__syscall_cp_asm
#endif
	.end	__syscall_cp_asm
	.cfi_endproc