70b0ddcad23a94dde81325d1802851bb998dd6bb blob 1403 bytes (raw)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
| | #autoload
# The option `-e' if given as the first argument says that we should
# complete only external commands and executable files. This and a
# `-' as the first argument is then removed from the arguments.
local args defs ffilt
zstyle -t ":completion:${curcontext}:commands" rehash && rehash
zstyle -t ":completion:${curcontext}:functions" prefix-needed && \
[[ $PREFIX != [_.]* ]] && \
ffilt='[(I)[^_.]*]'
defs=(
'commands:external command:_path_commands'
)
[[ -n "$path[(r).]" || $PREFIX = */* ]] &&
defs+=( 'executables:executable file:_files -g \*\(-\*\)' )
if [[ "$1" = -e ]]; then
shift
else
[[ "$1" = - ]] && shift
defs=( "$defs[@]"
'builtins:builtin command:compadd -Qk builtins'
"functions:shell function:compadd -k 'functions$ffilt'"
'aliases:alias:compadd -Qk aliases'
'suffix-aliases:suffix alias:_suffix_alias_files'
'global-aliases:global alias:compadd -Qk galiases'
'reserved-words:reserved word:compadd -Qk reswords'
'jobs:: _jobs -t'
'parameters:: _parameters -g "^*(readonly|association)*" -qS= -r "\n\t\- =[+"'
'parameters:: _parameters -g "*association*~*readonly*" -qS\[ -r "\n\t\- =[+"'
)
fi
args=( "$@" )
local -a cmdpath
if zstyle -a ":completion:${curcontext}" command-path cmdpath &&
[[ $#cmdpath -gt 0 ]]
then
local -a +h path
local -A +h commands
path=( $cmdpath )
fi
_alternative -O args "$defs[@]"
|
debug log:
solving 70b0ddcad ...
found 70b0ddcad in https://inbox.vuxu.org/zsh-users/20190313141513.hy6bw5lgc2jy3ttk@tarpaulin.shahaf.local2/
found f8188774d in https://git.vuxu.org/mirror/zsh/
preparing index
index prepared:
100644 f8188774d37282a2ceed9443285c063bfdd5fe21 Completion/Zsh/Type/_command_names
applying [1/1] https://inbox.vuxu.org/zsh-users/20190313141513.hy6bw5lgc2jy3ttk@tarpaulin.shahaf.local2/
diff --git a/Completion/Zsh/Type/_command_names b/Completion/Zsh/Type/_command_names
index f8188774d..70b0ddcad 100644
Checking patch Completion/Zsh/Type/_command_names...
Applied patch Completion/Zsh/Type/_command_names cleanly.
index at:
100644 70b0ddcad23a94dde81325d1802851bb998dd6bb Completion/Zsh/Type/_command_names
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).