zsh-workers
 help / color / mirror / code / Atom feed
1d76cf86d6f4e58bc575b7a0c53962b23d2ef8af blob 933 bytes (raw)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
 
#compdef fs_usage

local curcontext="$curcontext" state state_descr line ret=1
typeset -A opt_args

_arguments -s -C -A '-*' : \
  '-e[exclude fs_usage and the specified processes from sampling]' \
  '-w[use wider output]' \
  '*-f+[specify output filtering mode]:mode:(network filesys pathname exec diskio cachehit)' \
  '-b[annotate disk I/O events with BootCache info]' \
  '(-R -S -E)-t+[specify run timeout]:seconds' \
  '(-t)-R+[specify raw trace file to process]:raw trace file:_files' \
  '(-t)-S+[specify time to begin processing the trace file]:seconds' \
  '(-t)-E+[specify time to stop processing the trace file]:seconds' \
  '*: :->pid-or-pname' && ret=0

case $state in
  (pid-or-pname)
    if [[ -z $opt_args[-R] ]]; then
      _alternative "processes:: _pids" \
		  "processes-names:: _process_names -a" && ret=0
    else
      _message 'pid or process name in the trace file' && ret=0
    fi
    ;;
esac

return ret
debug log:

solving 1d76cf86d6 ...
found 1d76cf86d6 in https://git.vuxu.org/mirror/zsh/

Code repositories for project(s) associated with this public inbox

	https://git.vuxu.org/mirror/zsh/

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).