zsh-workers
 help / color / mirror / code / Atom feed
72d11864b3c9e20211a55c455c3c2a3dedc26cf8 blob 1373 bytes (raw)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
 
#compdef gcore

case $OSTYPE in
  solaris*)
    local -a content

    content=(
      'anon[anonymous private mappings]'
      'ctf[CTF type information]'
      'data[writable private file mappings]'
      'dism[DISM mappings]'
      'heap[process heap]'
      'ism[ISM mappings]'
      'rodata[read-only private file mappings]'
      'shanon[anonymous shared mappings]'
      'shfile[file-backed shared mappings]'
      'shm[System V shared memory]'
      'stack[process stack]'
      'symtab[symbol table sections for loaded files]'
      'text[readable and executable private file mappings]'
    )

    _arguments -s \
      '(-c -g)-p[use per-process core file repository]' \
      '(-c -p)-g[use global core file repository]' \
      '-F[force grabbing the target process]' \
      '(-p -g)-c[set core file content]: :_values -s + "content" $content' \
      '-o[set core file base name]:file base name:_files' \
      '*:pid:_pids'
  ;;
  netbsd*)
    _arguments \
      '-c+[write core file to specified file]:file:_files' \
      '*:pid:_pids'
    ;;
  freebsd*)
    _arguments -s \
      '-c+[write core file to specified file]:file:_files' \
      '-f[dump all available segments]' \
      '::executable:' \
      ':pid:_pids'
  ;;
  *)
    # GNU GDB gcore
    _arguments \
      '-o[set core file base name]:file base name:_files' \
      ':pid:_pids'
  ;;
esac
debug log:

solving 72d11864b ...
found 72d11864b in https://git.vuxu.org/mirror/zsh/

Code repositories for project(s) associated with this public inbox

	https://git.vuxu.org/mirror/zsh/

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).