zsh-workers
 help / color / mirror / code / Atom feed
de836a69697f91cd090a1fac1db180c4b9e44798 blob 3797 bytes (raw)

  1
  2
  3
  4
  5
  6
  7
  8
  9
 10
 11
 12
 13
 14
 15
 16
 17
 18
 19
 20
 21
 22
 23
 24
 25
 26
 27
 28
 29
 30
 31
 32
 33
 34
 35
 36
 37
 38
 39
 40
 41
 42
 43
 44
 45
 46
 47
 48
 49
 50
 51
 52
 53
 54
 55
 56
 57
 58
 59
 60
 61
 62
 63
 64
 65
 66
 67
 68
 69
 70
 71
 72
 73
 74
 75
 76
 77
 78
 79
 80
 81
 82
 83
 84
 85
 86
 87
 88
 89
 90
 91
 92
 93
 94
 95
 96
 97
 98
 99
100
101
102
103
104
105
106
107
108
109
110
111
112
113
114
115
116
117
118
119
120
121
122
123
124
125
126
127
128
129
130
131
132
133
134
135
136
137
138
139
140
141
142
143
144
145
146
 
#autoload

# This function can be used to separately complete parts of strings
# where each part may be one of a set of matches and different parts
# have different sets.
# Arguments are alternately arrays and separator strings. Arrays may
# be given by name or literally as words separated by white space in
# parentheses, e.g.:
#
#  _sep_parts '(foo bar)' @ hosts
#
# This will make this function complete the strings `foo' and `bar'.
# If the string on the line contains a `@', the substring after it
# will be completed from the array `hosts'. Of course more arrays
# may be given, each preceded by another separator string.
#
# This function understands the `-J group', `-V group', and
# `-X explanation' options.

local str arr sep test testarr tmparr prefix suffixes autosuffix
local matchflags opt group expl nm=$compstate[nmatches] opre osuf opts matcher

# Get the options.

zparseopts -D -a opts \
    'J+:=group' 'V+:=group' P: F: S: r: R: q 1 2 n 'X+:=expl' 'M+:=matcher'

# Get the string from the line.

opre="$PREFIX"
osuf="$SUFFIX"
str="$PREFIX$SUFFIX"
SUFFIX=""
prefix=""

# Walk through the arguments to find the longest unambiguous prefix.

while [[ $# -gt 1 ]]; do
  # Get the next array and separator.
  arr="$1"
  sep="$2"

  if [[ "$arr[1]" == '(' ]]; then
    tmparr=( ${=arr[2,-2]} )
    arr=tmparr
  fi

  # Is the separator on the line?

  [[ "$str" != *${sep}* ]] && break

  # Get the matching array elements.

  PREFIX="${str%%(|\\)${sep}*}"
  builtin compadd -O testarr "$matcher[@]" -a "$arr"
  [[ $#testarr -eq 0 && -n "$_comp_correct" ]] &&
    compadd -O testarr "$matcher[@]" -a "$arr"

  # If there are no matches we give up. If there is more than one
  # match, this is the part we will complete.

  (( $#testarr )) || return 1
  [[ $#testarr -gt 1 ]] && break

  # Only one match, add it to the prefix and skip over it in `str',
  # continuing with the next array and separator.

  prefix="${prefix}${testarr[1]}${sep}"
  str="${str#*${sep}}"
  shift 2
done

# Get the array to work upon.

arr="$1"
if [[ "$arr[1]" == '(' ]]; then
  tmparr=( ${=arr[2,-2]} )
  arr=tmparr
fi

if [[ $# -le 1 || "$str" != *${2}* ]]; then
  # No more separators, build the matches.

  PREFIX="$str"
  builtin compadd -O testarr "$matcher[@]" -a "$arr"
  [[ $#testarr -eq 0 && -n "$_comp_correct" ]] &&
    compadd -O testarr "$matcher[@]" -a "$arr"
fi

[[ $#testarr -eq 0 || ${#testarr[1]} -eq 0 ]] && return 1

# Now we build the suffixes to give to the completion code.

shift
suffixes=("")
autosuffix=()

while [[ $# -gt 0 && "$str" == *${1}* ]]; do
  # Remove anything up to the suffix.

  str="${str#*${1}}"

  # Again, we get the string from the line up to the next separator
  # and build a pattern from it.

  if [[ $# -gt 2 ]]; then
    PREFIX="${str%%${3}*}"
  else
    PREFIX="$str"
  fi

  # We incrementally add suffixes by appending to them the separators
  # and the strings from the next array that match the pattern we built.

  arr="$2"
  if [[ "$arr[1]" == '(' ]]; then
    tmparr=( ${=arr[2,-2]} )
    arr=tmparr
  fi

  builtin compadd -O tmparr "$matcher[@]" -a "$arr"
  [[ $#tmparr -eq 0 && -n "$_comp_correct" ]] &&
    compadd -O tmparr "$matcher[@]" - "$arr"

  suffixes=("${(@)^suffixes[@]}${(q)1}${(@)^tmparr}")

  shift 2
done

# If we were given at least one more separator we make the completion
# code offer it by appending it as a autoremovable suffix.

(( $# )) && autosuffix=(-qS "${(q)1}")

# Add the matches for each of the suffixes.

PREFIX="$pre"
SUFFIX="$suf"
for i in "$suffixes[@]"; do
  compadd -U "$group[@]" "$expl[@]" "$autosuffix[@]" "$opts[@]" \
          -i "$IPREFIX" -I "$ISUFFIX" -p "$prefix" -s "$i" -a testarr
done

# This sets the return value to indicate that we added matches (or not).

[[ nm -ne compstate[nmatches] ]]
debug log:

solving de836a696 ...
found de836a696 in https://git.vuxu.org/mirror/zsh/

Code repositories for project(s) associated with this public inbox

	https://git.vuxu.org/mirror/zsh/

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).