What am I missing?

What am I missing?

[skaller]

Why?

[root@ruby] ~/felix>ocamlc util.ml
[root@ruby] ~/felix>ocamlc util.mli
[root@ruby] ~/felix>ocaml
        Objective Caml version 2.02

# open Util;;
# string_of_list;;
Reference to undefined global `Util'
#

Re: What am I missing?

[Pierre Weis]

> Why?
> 
> [root@ruby] ~/felix>ocamlc util.ml
> [root@ruby] ~/felix>ocamlc util.mli
> [root@ruby] ~/felix>ocaml
>         Objective Caml version 2.02
> 
> # open Util;;
> # string_of_list;;
> Reference to undefined global `Util'

When you open a module you just add the list of exported names from
that module to your current environment (the interface of the module is
loaded). The corresponding implementation must be loaded (the code has
to be linked), before using any of the names defined in the
implementation. Use the pragma #load in the interactive environment to
link the code:

        Objective Caml version 2.02

# open Util;;
# #load"util.cmo";;
# string_of_list;;
- : 'a list -> string = <fun>

Best regards,

Pierre Weis

INRIA, Projet Cristal, Pierre.Weis@inria.fr, http://cristal.inria.fr/~weis/

Tree of a certain class:

[Peter Schrammel]

I wrote a Program:
type 'i tree =
    Empty
  | Item of 'i
  | Section of 'i * 'i

class ['i] ctree =
  object (self : 'a)
    val mutable content : 'i tree = Empty

    method get = content
        
end

class debug =
  object
    method debug = ()
  end

class dtree =
  object
    inherit [#debug] ctree
  end

But the compiler gives me the error:

Some type variables are unbound in this type:
  class dtree :
    object val mutable content : (#debug as 'a) tree method get : 'a
tree end
The method get has type #debug tree where .. is unbound
make: *** [test.cmo] Error 2   

How can make trees of a certain (sub)class ? (I hope there's a simple
solution)

Regards,
Peter
--
Peter Schrammel
UniBw-Muenchen 106/2/116
85579 Neubiberg
ICQ: 5469131

Re: Tree of a certain class:

[Pierre Boulet]

> class dtree =
>   object
>     inherit [#debug] ctree
>   end
> 
> But the compiler gives me the error:
> 
> Some type variables are unbound in this type:
>   class dtree :
>     object val mutable content : (#debug as 'a) tree method get : 'a
> tree end
> The method get has type #debug tree where .. is unbound
> make: *** [test.cmo] Error 2   
> 
Here is a simple solution: just write your class as:

class ['a] dtree =
  object
    constraint 'a = #debug
    inherit ['a] ctree
  end

Indeed, no type variable can stay unbounded (hence the ['a]) in a
class definition. #debug (equivalent to < debug : unit; .. >) is an
abbreviation that hides a type variable (the elipsis: ..).

-- 
Pierre.

Re: Tree of a certain class:

[Sylvain BOULM'E]

Hello,

Actually, #debug is an abbrevation for 
 <method debug : unit; ..>
where ".." is a row type variable, you may imagine as universally quantified.
And methods of a class are not allowed to be polymorphic. Only classes are.
So, you have to bound this row variable to a type parameter of the class. 

* So a general solution is :

class ['a] dtree =
  object
    constraint 'a=#debug
    inherit ['a] ctree
  end

* But if you want only a "debug tree", you may write :

class dtree =
  object
    inherit [debug] ctree
  end

Regards,

Sylvain.

Re: Tree of a certain class:

[Jerome Vouillon]

On Fri, Sep 24, 1999 at 10:15:52AM +0200, Peter Schrammel wrote:
> I wrote a Program:
> type 'i tree =
>     Empty
>   | Item of 'i
>   | Section of 'i * 'i
> 
> class ['i] ctree =
>   object (self : 'a)
>     val mutable content : 'i tree = Empty
> 
>     method get = content
>         
> end
> 
> class debug =
>   object
>     method debug = ()
>   end
> 
> class dtree =
>   object
>     inherit [#debug] ctree
>   end
> 
> But the compiler gives me the error:
> 
> Some type variables are unbound in this type:
>   class dtree :
>     object val mutable content : (#debug as 'a) tree method get : 'a
> tree end
> The method get has type #debug tree where .. is unbound
> make: *** [test.cmo] Error 2   
> 
> How can make trees of a certain (sub)class ? (I hope there's a simple
> solution)

Depending on your needs, you can either write
    class dtree =
      object
        inherit [debug] ctree
    end
or
    class ['a] dtree =
      object
        constraint 'a = #debug
        inherit ['a] ctree
    end
In the first case, the type of the contained object is fixed. In the
second case it is only required to be an instance of type
   #debug = < debug : unit; .. >
So, if you write a subclass debug2 of class debug, an object of type
"debug2 dtree" will contain objects of type "debug2".

Regards,

-- Jérôme