Re: [Caml-list] Unix module and threads

[David Brown <caml-list@davidb.org>]

[-- Attachment #1: Type: text/plain, Size: 567 bytes --]

On Sun, Sep 05, 2004 at 11:00:04AM +0300, Janne Hellsten wrote:

> I wonder what happens if I call [Unix.chdir foo] from two different 
> threads, with two different directories?

I think this is going to depend on how threads are implemented, and as I
understand it, that varies depending on what platform, and which compiler
you are using.

I've attached a small program that will help determine this.  As far as I
can tell, on Linux, there seems to only be one current directory shared
between all of the threads.  This is the same for native and byte-code.

Dave

[-- Attachment #2: threa.ml --]
[-- Type: text/plain, Size: 733 bytes --]

(* Show chdir and threads. *)

let phase = ref 0
let phase_lock = Mutex.create ()
let phase_cond = Condition.create ()

let wait_phase n =
  Mutex.lock phase_lock;
  while !phase != n do
    Condition.wait phase_cond phase_lock
  done;
  Mutex.unlock phase_lock

let mark_phase n =
  Mutex.lock phase_lock;
  phase := n;
  Condition.signal phase_cond;
  Mutex.unlock phase_lock

let thread_a () =
  wait_phase 1;
  Unix.chdir "a";
  mark_phase 2;
  wait_phase 3

let thread_b () =
  (* Execution starts here. *)
  mark_phase 1;
  wait_phase 2;
  Printf.printf "result dir: %S\n" (Unix.getcwd ());
  mark_phase 3

let () =
  let a = Thread.create thread_a () in
  let b = Thread.create thread_b () in
  Thread.join a;
  Thread.join b