Simple clock

Simple clock

[romildo]

Hello.

I am willing to write a very very simple clock in
OCaml, but do not know exactly how to do it.

I would like to start with a console program
that just prints the current time every second.
The output would be something like the following:

$ simpleclock
15:15:58
15:15:59
15:16:00
15:16:01

I want to receive sugestions on how to implement
this.

Regards,

Romildo

Re: [Caml-list] Simple clock

[Keith Wansbrough]

> 
> $ simpleclock
> 15:15:58
> 15:15:59
> 15:16:00
> 15:16:01
> 
> I want to receive sugestions on how to implement
> this.

Thread.delay
Unix.time
Unix.localtime

--KW 8-)
-- 
Keith Wansbrough <kw217@cl.cam.ac.uk>
http://www.cl.cam.ac.uk/users/kw217/
University of Cambridge Computer Laboratory.

Re: [Caml-list] Simple clock

[Lars Nilsson]

On Tue, 14 Dec 2004 17:38:50 +0000, Keith Wansbrough
<Keith.Wansbrough@cl.cam.ac.uk> wrote:
> Thread.delay
> Unix.time
> Unix.localtime

Or Unix.select instead of Thread.delay, for that tried-and-true
solution that will give you sub-second sleep capability.

  ignore(Unix.select [] [] [] 0.5)

Lars Nilsson

Re: [Caml-list] Simple clock

[romildo]

[-- Attachment #1: Type: text/plain, Size: 613 bytes --]

On Tue, Dec 14, 2004 at 01:17:01PM -0500, Lars Nilsson wrote:
> On Tue, 14 Dec 2004 17:38:50 +0000, Keith Wansbrough
> <Keith.Wansbrough@cl.cam.ac.uk> wrote:
> > Thread.delay
> > Unix.time
> > Unix.localtime
> 
> Or Unix.select instead of Thread.delay, for that tried-and-true
> solution that will give you sub-second sleep capability.
> 
>   ignore(Unix.select [] [] [] 0.5)

Here is my simple clock in Ocaml. Have I done it right?
Any comments?

Particularly, the while, print_tm and print_newline execution
time is not counted. Would that introduce an accurace in
my clock? If so, is that inevitable?

Romildo

[-- Attachment #2: simple-clock.ml --]
[-- Type: text/plain, Size: 496 bytes --]

(* simple-clock.ml
   Repeatedly prints the current time at the standard output,
   at intervals of 1 sec

   How to compile:

   ocamlopt unix.cmxa simple-clock.ml -o simple-clock
*)

open Unix

let print_tm tm =
  print_int tm.tm_hour;
  print_char ':';
  print_int tm.tm_min;
  print_char ':';
  print_int tm.tm_sec

let simple_clock () =
  while true do
    print_tm (Unix.localtime (Unix.time ()));
    print_newline ();
    ignore (Unix.select [] [] [] 1.0)
  done

let _ = simple_clock ()

Re: [Caml-list] Simple clock

[romildo]

[-- Attachment #1: Type: text/plain, Size: 565 bytes --]

On Tue, Dec 14, 2004 at 05:38:50PM +0000, Keith Wansbrough wrote:
> > 
> > $ simpleclock
> > 15:15:58
> > 15:15:59
> > 15:16:00
> > 15:16:01
> > 
> > I want to receive sugestions on how to implement
> > this.
> 
> Thread.delay
> Unix.time
> Unix.localtime

I have tried the following program, but its
compilation fails with the message:

$ ocamlopt -thread threads.cmxa unix.cmxa simple-clock.ml -o simple-clock
No implementations provided for the following modules:
  Unix referenced from /usr/lib/ocaml/threads/threads.cmxa(Thread)

What does that mean?

Romildo

[-- Attachment #2: simple-clock.ml --]
[-- Type: text/plain, Size: 512 bytes --]

(* simple-clock.ml
   Repeatedly prints the current time at the standard output,
   at intervals of 1 sec

   How to compile:

   ocamlopt -thread threads.cmxa unix.cmxa simple-clock.ml -o simple-clock
*)

open Unix
open Thread

let print_tm tm =
  print_int tm.tm_hour;
  print_char ':';
  print_int tm.tm_min;
  print_char ':';
  print_int tm.tm_sec

let simple_clock () =
  while true do
    print_tm (Unix.localtime (Unix.time ()));
    print_newline ();
    Thread.delay 1.0
  done

let _ = simple_clock ()

Re: [Caml-list] Simple clock

[Ville-Pertti Keinonen]

On Tue, 2004-12-14 at 18:39 -0200, romildo@uber.com.br wrote:

> Particularly, the while, print_tm and print_newline execution
> time is not counted. Would that introduce an accurace in
> my clock? If so, is that inevitable?

It'll always print the correct time, at approximately one-second
intervals, but as you suspect, it'll drift over time.

What you probably want for the delay is something like:

ignore (Unix.select [] [] [] (1.0 -. (fst (modf (Unix.gettimeofday
())))))

Unix.gettimeofday () returns the time as a floating point number with
reasonable accuracy, modf splits it into fractional and integral parts,
fst selects the first one (the fractional part), so the select returns
at (or as close to as possible) the next integral second.

Re: [Caml-list] Simple clock

[skaller]

On Wed, 2004-12-15 at 07:43, romildo@uber.com.br wrote:

> $ ocamlopt -thread threads.cmxa unix.cmxa simple-clock.ml -o simple-clock
> No implementations provided for the following modules:
>   Unix referenced from /usr/lib/ocaml/threads/threads.cmxa(Thread)
> 
> What does that mean?

Try unix.cmxa before thread.cmxa

-- 
John Skaller, mailto:skaller@users.sf.net
voice: 061-2-9660-0850, 
snail: PO BOX 401 Glebe NSW 2037 Australia
Checkout the Felix programming language http://felix.sf.net

Re: [Caml-list] Simple clock

[Kurt Welgehausen]

(*** Here are a few things to investigate if you're learning ocaml *)

(*** "**" in opening comment, for ocamldoc *)
(** simple-clock.ml
   Repeatedly prints the current time at the standard output,
   at intervals of 1 sec

   How to compile:

   ocamlopt unix.cmxa simple-clock.ml -o simple-clock
*)

(*** You don't need to open the module if you qualify names with "Unix." *)
(*open Unix*)

(*** It's not important in such a simple program, but you can hide
     functions like print_tm that are used only by one other function *)
(*let print_tm tm =
  print_int tm.tm_hour;
  print_char ':';
  print_int tm.tm_min;
  print_char ':';
  print_int tm.tm_sec
*)

let simple_clock () =
  let print_tm tm =
    (*** so you don't get "7:8:9" *)
    Printf.printf "%2d:%02d:%02d\n"
                        tm.Unix.tm_hour tm.Unix.tm_min tm.Unix.tm_sec;
    flush stdout in
  (*** This works, but in ocaml you can do it in a more functional style *)
(*  while true do
    print_tm (Unix.localtime (Unix.time ()));
    print_newline ();
    ignore (Unix.select [] [] [] 1.0)
  done
*)
  let rec loop () =
    print_tm (Unix.localtime (Unix.time ()));
    ignore (Unix.select [] [] [] (1. -. (fst (modf (Unix.gettimeofday ())))));
    loop () in
  loop () in
simple_clock ()

(*let _ = simple_clock ()*)

(*** It's easier to read if you remove my comments and the code that
     I've commented out. Have fun *)

Re: [Caml-list] Simple clock

[Evan Martin]

On Tue, Dec 14, 2004 at 09:20:13PM -0600, Kurt Welgehausen wrote:
>     Printf.printf "%2d:%02d:%02d\n"
>                         tm.Unix.tm_hour tm.Unix.tm_min tm.Unix.tm_sec;
>     flush stdout in

Or just
Printf.printf "%2d:%02d:%02d\n%!"
              tm.Unix.tm_hour tm.Unix.tm_min tm.Unix.tm_sec

>From the docs on conversion characters:
  !: take no argument and flush the output.

-- 
Evan Martin
martine@danga.com
http://neugierig.org