Re: [Caml-list] Why are modules handled differently by the interpreter and the compiler

["Grégoire Henry" <henry@pps.univ-paris-diderot.fr>]

[-- Attachment #1: Type: text/plain, Size: 767 bytes --]

> What could be implemented as an extension is a #use_as_module
> directive that adds the implicit module. This could be in deed
> useful for debugging, especially when it overlooks the mli file if
> present - if you #load, the definition hiding of the mli file takes
> place, and you cannot see unexported definitions anymore. Of course,
> this is sometimes in the way when you test things out.
> 
> Now that compiler-libs is installed this extension could probably
> even be implemented outside the compiler. Anyone up for it?

Well, here it is:

  $ ocamlmktop -o myocaml mod_use.ml
  $ cat test.ml
  let x = 53
  $ ./myocaml
        OCaml version 4.00.1

  # #mod_use "test.ml";;
  module Test : sig val x : int end
  # Test.x;;
  - : int = 53

Regards,
Grégoire

[-- Attachment #2: mod_use.ml --]
[-- Type: text/plain, Size: 935 bytes --]


open Parsetree

let filter_out_directives lb =
  List.concat
    (List.map
       (function
         | Ptop_def s -> s
         | Ptop_dir _ -> [])
       lb)

let parse_mod_use_file parse_use_file name lb =
  let modname =
    String.capitalize (Filename.chop_extension (Filename.basename name))
  in
  let items = filter_out_directives (parse_use_file lb) in
  [ Ptop_def
      [{pstr_desc =
        Pstr_module ( Location.mknoloc modname ,
                      { pmod_desc = Pmod_structure items;
                        pmod_loc = Location.none } );
        pstr_loc = Location.none }] ]

let dir_mod_use name =
  let parse_use_file = !Toploop.parse_use_file in
  Toploop.parse_use_file := parse_mod_use_file parse_use_file name;
  ignore (Toploop.use_file Format.std_formatter name);
  Toploop.parse_use_file := parse_use_file

let () =
  Hashtbl.add Toploop.directive_table "mod_use"
    (Toploop.Directive_string dir_mod_use)