Re: [Caml-list] Referencing a functor type

[Nick Betteridge <lists.nick.betteridge@gmail.com>]

Hi,

Really grateful for help on this and thanks for taking time to write
back. Octachron has just emailed me to suggest swapping two lines to
make sure the type system knows that the existential type local_t inside
cm1 and l_k1 are the same (from my original example) - ie:

  let module C1' = (val cs1' : Cipher with type local_t = 'a) in
  let LK (local1', cs1') = l_k1 in
  let signature = C1'.local_sign local1' (Cstruct.create 23) in

should be

  let LK (local1', cs1') = l_k1 in
  let module C1' = (val cs1' : Cipher with type local_t = 'a) in
  let signature = C1'.local_sign local1' (Cstruct.create 23) in

Your solution, of course :) , also works - what exactly does the '_' do in:

type _ local_key

- am I right in thinking that this was how the type system figured
everything out?

Thanks again for your time,

Cheers
Nick


On 18/01/16 14:45, Runhang Li wrote:
> module Cstruct = struct
>   type t = string
>   let create n = Obj.magic ()
> end
> 
> module type Cipher = sig
> 
>   type local_t
>   type remote_t
> 
>   val local_create : unit -> local_t
>   val local_sign : local_t -> Cstruct.t -> Cstruct.t
>   val remote_create : Cstruct.t -> remote_t
>   val remote_validate : remote_t -> Cstruct.t -> bool
> 
> end
> 
> module MMMake_cipher (Cipher_impl : Cipher) = struct
>   type local_t = Cipher_impl.local_t
>   type remote_t = Cipher_impl.remote_t
> 
>   let local_create = Cipher_impl.local_create
>   let local_sign = Cipher_impl.local_sign
>   let remote_create = Cipher_impl.remote_create
>   let remote_validate = Cipher_impl.remote_validate
> end
> 
> 
> type _ local_key =
>     LK : 'a * (module Cipher with type local_t = 'a) -> 'a local_key
> 
> type local_key_list =
>   | KNil :  local_key_list
>   | KCons : 'a local_key * local_key_list -> local_key_list
> 
> type _ cipher_module =
>     CM : (module Cipher with type local_t = 'a) -> 'a cipher_module
> 
> type cipher_module_list =
>   | MNil :  cipher_module_list
>   | MCons : 'a cipher_module * cipher_module_list -> cipher_module_list
> 
> type self_t = {
>   mutable modules : cipher_module_list;
>   mutable locals : local_key_list
> }
> 
> module Cipher1 : Cipher = struct
>   type local_t
>   type remote_t
>   let local_create = fun _ -> Obj.magic ()
>   let local_sign = fun _ _ -> Obj.magic ()
>   let remote_create = fun _ -> Obj.magic ()
>   let remote_validate = fun _ _ -> Obj.magic ()
> end
> 
> module Cipher2 : Cipher = struct
>   type local_t
>   type remote_t
>   let local_create = fun _ -> Obj.magic ()
>   let local_sign = fun _ _ -> Obj.magic ()
>   let remote_create = fun _ -> Obj.magic ()
>   let remote_validate = fun _ _ -> Obj.magic ()
> end
> 
> module C1x = MMMake_cipher(Cipher1)
> module C2x = MMMake_cipher(Cipher2)
> 
> 
> let () =
>   let cs1 = (module C1x : Cipher with type local_t = Cipher1.local_t) in
>   let cs2 = (module C2x : Cipher with type local_t = Cipher2.local_t) in
>   let module C1 = (val cs1 : Cipher with type local_t = Cipher1.local_t) in
>   let module C2 = (val cs2 : Cipher with type local_t = Cipher2.local_t) in
>   let local1 = C1.local_create () in
>   let local2 = C2.local_create () in
>   let l_k1 = LK (local1, cs1) in
>   let l_k2 = LK (local2, cs2) in
>   let cm1 = CM (cs1) in
>   let cm2 = CM (cs2) in
>   ignore (C1.local_sign local1 (Cstruct.create 23));
>   let self = {
>     modules = MCons (cm1, MCons(cm2, MNil));
>     locals = KCons (l_k1, KCons(l_k2, KNil));
>   } in
>   let CM cs1' = cm1 in
>   let module C1' = (val cs1' : Cipher with type local_t = 'a) in
>   let LK (local1', cs1') = l_k1 in
>   let signature = C1'.local_sign local1' (Cstruct.create 23) in
>   Printf.printf "OK"