Re: [Caml-list] polymorphic variants in match statements

["Milan Stanojević" <milanst@gmail.com>]

Thanks a lot, Jacques!
This helped my understanding a lot.

I only wonder if maybe this (and other type checking issues) could be
documented in a better way. For example I couldn't find any links to
your papers on OCaml website


2012/1/23 Jacques Garrigue <garrigue@math.nagoya-u.ac.jp>:
> On 2012/01/24, at 9:53, Milan Stanojević wrote:
>
>> Hi, we're trying to understand the type inference with polymorphic
>> variants in match statements. This is a simplification of an actual
>> case that happened in practice.
>>
>> 1)
>> let f i a =
>>  match i, a with
>>  | true, `A -> `B
>>  | false, x -> x
>>
>> fails with
>> File "foo.ml", line 4, characters 16-17:
>> Error: This expression has type [< `A ]
>>       but an expression was expected of type [> `B ]
>>       The first variant type does not allow tag(s) `B
>>
>> 2) changing false to _
>> let f i a =
>>  match i, a with
>>  | true, `A -> `B
>>  | _, x -> x
>>
>> this succeeds with
>> val f : bool -> ([> `A | `B ] as 'a) -> 'a
>>
>> 3) changing x in (1) to _ , and using a on the right side
>> let f i a =
>>  match i, a with
>>  | true, `A -> `B
>>  | false, _ -> a
>>
>> this fails in the same way as (1)
>>
>> 4) finally adding another case to match statement
>> let f i a =
>>  match i, a with
>>  | true, `A -> `B
>>  | false, x -> x
>>  | true, x -> x
>>
>> this succeeds with the same type as (2)
>>
>>
>> So it seems there is some interaction between type inference and
>> exhaustivnest of the match statements.
>>
>> Can someone shed some light on what is going on here?
>
> Indeed. The basic idea is to close variant types when leaving them
> open would make the pattern matching non-exhaustive.
> Here, if we assume that a has type [`A | `B], then the pattern-matching
> becomes non-exhaustive, so the type inferred is just [`A]
> (i.e. the list of all constructors appearing inside the patterns at this position).
>
> Actually, the theory is a bit more complicated, and the full details are
> in the following paper, but you should just expect the above behavior
> in practice.
>
>        Typing deep pattern-matching in presence of polymorphic variants.
>        http://www.math.nagoya-u.ac.jp/~garrigue/papers/index.html
>
> Note that there is also another way to make (1) type, without adding
> new cases
>
>  let f i a =
>    match i, a with
>    | true, `A -> `B
>    | false, (`A as x) -> x;;
>  val f : bool -> [< `A ] -> [> `A | `B ] = <fun>
>
> Here we have removed the connection between a and the output,
> allowing `A to be combine with `B without changing the type of a.
>
> Hope this helps.
>
> Jacques Garrigue
>