Re: [Caml-list] recursive module type

[Gabriel Scherer <gabriel.scherer@gmail.com>]

I did not need such form of self-reference to build converter from a
set to another.

(* binary converter functor *)
module SetConverter (S1 : Set.S) (S2 : Set.S) : sig
  val convert : (S1.elt -> S2.elt) -> (S1.t -> S2.t)
end = struct
  let convert f s1 =
    S1.fold (fun e s2 -> S2.add (f e) s2) s1 S2.empty
end

(* currified version as a Set.S overlay *)
module SetWithConverter (E : Set.OrderedType) : sig
  include Set.S
  module Converter (S2 : Set.S) : sig
    val convert : (elt -> S2.elt) -> (t -> S2.t)
  end
end = struct
  module S1 = Set.Make(E)
  include S1
  module Converter (S2:Set.S) = SetConverter(S1)(S2)
end


On Sat, May 4, 2013 at 2:23 PM, Michaël Lienhardt
<michael.lienhardt@inria.fr> wrote:
> Hello,
>
> I would like to define some recursive module type in caml, like
> module type S = sig
>  ...
>  module Toto(M : S) : sig
>   ...
>  end
> end
>
> More precisely, I'd like to extend the Set module available in the ocaml
> distribution with a function that convert a set into another set.
> Intuitively, I came up with the following signature S, which is not accepted
> by ocaml (Error: Unbound module type S):
>
>   module type S = sig
>
>     include Set.S
>
>     module Convert : functor(SetTarget : S) -> sig
>       val convert : (elt -> SetTarget.elt) -> t -> SetTarget.t
>     end
>   end
>
> Is there a way to define such a module type in ocaml, and if not, is there a
> theoretical reason for this not being possible?
>
> Thanks,
> Michael Lienhardt
>
> --
> Caml-list mailing list.  Subscription management and archives:
> https://sympa.inria.fr/sympa/arc/caml-list
> Beginner's list: http://groups.yahoo.com/group/ocaml_beginners
> Bug reports: http://caml.inria.fr/bin/caml-bugs