Re: HTML foreground and background colors being the same... poll time!

[Felix Lee <flee@teleport.com>]

this is a tcl function I've been using for choosing
contrasting colors.  it's not perfect (like, it tends to
think similar greens have more contrast than they do), but
it does a good job most of the time, especially if you're
only interested in choosing between very different colors
like white and black.

proc color/contrasting {w color {colors {black white}}} {
##
## Returns the color in $colors that most contrasts with
## $color in window $w.  Currently, just looks at luminance.

    set y0 [color/luminance $w $color]
    set best $color
    set dist 0
    foreach c $colors {
	set y [color/luminance $w $c]
	set d [expr {abs($y - $y0)}]
	if {$dist < $d} {
	    set best $c
	    set dist $d
	}
    }
    return $best
}

proc color/luminance {w color} {
##
## Returns the (YIQ-model) luminance of $color in window $w.

    set* {r g b} [winfo rgb $w $color]
    expr {.299 * $r / 65535 + .587 * $g / 65535 + .114 * $b / 65535}
}

proc set* {names values} {
    foreach name $names value $values {
	upvar $name var
	set var $value
    }
}