Gnus development mailing list
 help / color / mirror / Atom feed
* New make.bat, give it a try
@ 2003-03-05 10:49 Frank Schmitt
  2003-03-05 17:16 ` Peter Wu
  2003-03-06 11:00 ` Han Pilmeyer
  0 siblings, 2 replies; 23+ messages in thread
From: Frank Schmitt @ 2003-03-05 10:49 UTC (permalink / raw)


[-- Attachment #1: Type: text/plain, Size: 481 bytes --]

Hello

I just finished a new make.bat file which should work with both emacs
and xemacs and emulate the ./configure; make circle better than the old
one.

I'd be really interested in your experiences with it, I have tested it
with Emacs 21.3 and XEmacs 21.4.11 under Windows XP, therefor I'd be
especially interested if everything works under Win 9x, too.

WARNING: This is experimental stuff, backup everything before you start
it and don't blame me if it eats your children :-)


[-- Attachment #2: New make.bat --]
[-- Type: application/octet-stream, Size: 4527 bytes --]

@echo off

rem Written by Frank Schmitt <ich@frank-schmitt.net>
rem based on the work by David Charlap (shamino@writeme.com)
rem .
rem Clear PWD so emacs doesn't get confused
set GNUS_PWD_SAVE=%PWD%
set PWD=

if "%1" == "" goto usage

rem Emacs 20.7 no longer includes emacs.bat. Use emacs.exe if the batch file is
rem not present -- this also fixes the problem about too many parameters on Win9x.
if exist %1\emacs.bat goto ebat
if exist %1\emacs.exe goto eexe
if exist %1\xemacs.exe goto xexe
goto noemacs

:ebat
set EMACS=emacs.bat
set GNUS_INFO_DIR=%1\..\info
set GNUS_LISP_DIR=%1\..\lisp\gnus
set GNUS_ETC_DIR=%1\..\lisp\gnus
echo Using emacs.bat
goto lisp

:eexe
set EMACS=emacs.exe
set GNUS_INFO_DIR=%1\..\info
set GNUS_LISP_DIR=%1\..\lisp\gnus
set GNUS_ETC_DIR=%1\..\lisp\gnus
echo Using emacs.exe
goto lisp
      
:xexe      
set EMACS=xemacs.exe
set GNUS_INFO_DIR=%1\..\..\xemacs-packages\info
set GNUS_LISP_DIR=%1\..\..\xemacs-packages\lisp\gnus
set GNUS_ETC_DIR=%1\..\..\xemacs-packages\etc
echo Using xemacs.exe   
goto lisp

:lisp
set EMACSBATCH=call %1\%EMACS% -no-site-file -batch -q
cd lisp
if exist gnus-load.el del gnus-load.el
%EMACSBATCH% -l ./dgnushack.el -f dgnushack-make-cus-load .
%EMACSBATCH% -l ./dgnushack.el -f dgnushack-make-auto-load .
%EMACSBATCH% -l ./dgnushack.el -f dgnushack-make-load
%EMACSBATCH% -l ./dgnushack.el -f dgnushack-compile
if not "%2" == "/copy" goto infotest
if not exist %GNUS_LISP_DIR% mkdir %GNUS_LISP_DIR%
attrib -r %GNUS_LISP_DIR%\*
copy *.el* %GNUS_LISP_DIR%
goto infotest

:infotest
cd ..\texi
if exist sieve del sieve
makeinfo sieve.texi
if exist sieve goto minfo 
REM It seems that makeinfo isn't available
set EMACSINFO=%EMACSBATCH% -l infohack.el -f batch-makeinfo
echo Using infohack.el, if you've got makeinfo.exe put in in PATH
goto info

:minfo
set EMACSINFO=makeinfo  
echo Using makeinfo
goto info

:info
%EMACSINFO% message.texi
%EMACSINFO% emacs-mime.texi
%EMACSINFO% gnus.texi
%EMACSINFO% sieve.texi
%EMACSINFO% pgg.texi
if not "%2" == "/copy" goto nocopy
if not exist %GNUS_INFO_DIR% mkdir %GNUS_INFO_DIR%
copy gnus       %GNUS_INFO_DIR%
copy gnus-?     %GNUS_INFO_DIR%
copy gnus-??    %GNUS_INFO_DIR%
copy message    %GNUS_INFO_DIR%
copy message-?  %GNUS_INFO_DIR%
copy emacs-mime %GNUS_INFO_DIR%
copy sieve      %GNUS_INFO_DIR%
copy pgg.info   %GNUS_INFO_DIR%
echo Maybe you should add the following lines to %GNUS_INFO_DIR%\dir:
echo.
echo * PGG: (pgg).		Emacs interface to various PGP implementations.
echo * Sieve: (sieve).	Managing Sieve scripts in Emacs.
echo.

:etc
cd ..\etc
if not exist %GNUS_ETC_DIR% mkdir %GNUS_ETC_DIR%
copy gnus-tut.txt %GNUS_ETC_DIR%
if not exist %GNUS_ETC_DIR%\gnus mkdir %GNUS_ETC_DIR%\gnus
attrib -r %GNUS_ETC_DIR%\gnus\*
copy .\gnus\* %GNUS_ETC_DIR%\gnus\
if not exist %GNUS_ETC_DIR%\smilies mkdir %GNUS_ETC_DIR%\smilies
attrib -r %GNUS_ETC_DIR%\smilies\*
copy .\smilies\* %GNUS_ETC_DIR%\smilies\
goto done

:nocopy
echo You chose not to copy the files, therefore you should add the 
echo following lines to the TOP of your [X]emacs customization file:
echo.
echo (add-to-list 'load-path "c:\Path\to\gnus\lisp")
echo (if (featurep 'xemacs)
echo     (add-to-list 'Info-directory-list "c:/Path/to/gnus/texi/")
echo   (add-to-list 'Info-default-directory-list "c:/Path/to/gnus/texi/")
echo.
echo Replace c:/Path/to/gnus with the Path where your new Gnus is (that's here
echo and yes, you've got to use forward slashes).

:done
cd ..
goto end

:noemacs
echo Unable to find emacs.exe or xemacs.exe on the path you specified!
echo. 
goto usage

:usage
echo Usage: make.bat :emacs-dir: [/copy]
echo.
echo where: :emacs-dir: is the directory your emacs.exe respectively xemacs.exe
echo        resides in, e.g. G:\Programme\XEmacs\XEmacs-21.4.11\i586-pc-win32\
echo        or G:\Emacs\bin
echo        /copy indicates that the compiled files should be copied to your
echo             emacs lisp, info, and etc directories
echo        WARNING: This means that your old Gnus will be overridden!
echo.
echo Note: If you have Emacs/w3 you should set the environment variable 
echo       W3DIR to the directory where w3 is installed eg.
echo                 set W3DIR=d:\lisp\w3-4.0pre46\lisp

rem Restore PWD so whoever called this batch file doesn't get confused
set PWD=%GNUS_PWD_SAVE%
set GNUS_PWD_SAVE=
set EMACSBATCH=
set GNUS_LISP_DIR=
set GNUS_INFO_DIR=
set GNUS_ETC_DIR=
:end

[-- Attachment #3: Type: text/plain, Size: 158 bytes --]



-- 
One Ring to rule them all, One Ring to find them,
One Ring to bring them all and in the darkness bind them
In the Land of Mordor where the Shadows lie.

^ permalink raw reply	[flat|nested] 23+ messages in thread
end of thread, other threads:[~2003-03-10  7:04 UTC | newest]

Thread overview: 23+ messages (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2003-03-05 10:49 New make.bat, give it a try Frank Schmitt
2003-03-05 17:16 ` Peter Wu
2003-03-05 17:40   ` Frank Schmitt
     [not found]     ` <86heag1wph.fsf@vanilla.zzz>
2003-03-06 15:22       ` Frank Schmitt
2003-03-07  5:27         ` Peter Wu
2003-03-07 17:02           ` Kai Großjohann
2003-03-07 18:28           ` Frank Haun
2003-03-08 14:51             ` Peter Wu
2003-03-08 17:40               ` Frank Haun
2003-03-06 11:00 ` Han Pilmeyer
2003-03-06 11:29   ` Frank Schmitt
2003-03-06 12:00     ` Even newer make.bat (was: New make.bat, give it a try) Frank Schmitt
2003-03-06 23:33       ` Even newer make.bat Frank Haun
2003-03-07  8:41         ` Frank Schmitt
2003-03-07 18:22           ` Frank Haun
2003-03-09 14:14       ` Reiner Steib
2003-03-10  7:04         ` Frank Schmitt
2003-03-06 12:15     ` New make.bat, give it a try Norbert Koch
2003-03-06 12:22     ` Han Pilmeyer
2003-03-06 16:21       ` Frank Schmitt
2003-03-06 17:23         ` Han Pilmeyer
2003-03-06 18:37           ` Frank Schmitt
2003-03-06 21:56             ` Han Pilmeyer

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).