Re: htmlified mail

[merlyn@stonehenge.com (Randal L. Schwartz)]

>>>>> "Bill" == Bill White <billw@wolfram.com> writes:

Bill> I'm seeing a lot of this crap nowadays.  Is this MS Lookout! output?

Apparently, MS Outlook (not Outlook Express) for Windows 2K does not
have a global "send plaintext mail only".  To send plaintext mail,
the address must be added to an address book, and then for that specific
address, an option must be individually selected to say "send plaintext".

This is pure evil.

I wrote the following Perl program as a hasty response, and pipe everything
through it that matches "Content-type:.*boundary" in the header.  It's
harmless on *real* MIME content, other than eating a bit of CPU.
Requires the MIME::Tools distribution from teh CPAN.

    #!/usr/bin/perl -w
    use strict;
    $|++;

    my $envelope = <STDIN>;

    use MIME::Parser;
    use MIME::Entity;

    my $parser = MIME::Parser->new;
    $parser->output_to_core(1);
    $parser->tmp_to_core(1);

    my $ent = eval { $parser->parse(\*STDIN) }; die "$@" if $@;

    if ($ent->effective_type eq "multipart/alternative"
        and $ent->parts == 2
        and $ent->parts(0)->effective_type eq "text/plain"
        and $ent->parts(1)->effective_type eq "text/html") {

      my $newent = MIME::Entity->build(Data =>
                                       $ent->parts(0)->body_as_string .
                                       "\n\n[[HTML alternate version deleted]]\n");
      $ent->parts([$newent]);	
      $ent->make_singlepart;
      $ent->sync_headers(Length => 'COMPUTE', Nonstandard => 'ERASE');
    }

    print $envelope;
    $ent->print;


-- 
Randal L. Schwartz - Stonehenge Consulting Services, Inc. - +1 503 777 0095
<merlyn@stonehenge.com> <URL:http://www.stonehenge.com/merlyn/>
Perl/Unix/security consulting, Technical writing, Comedy, etc. etc.
See PerlTraining.Stonehenge.com for onsite and open-enrollment Perl training!