Re: [musl] [Patch] src/math/i386/remquo.s: remove conditional branch, shorter bit twiddling

["Stefan Kanthak" <stefan.kanthak@nexgo.de>]

[-- Attachment #1: Type: text/plain, Size: 601 bytes --]

Alexander Monakov <amonakov@ispras.ru> wrote:

> On Wed, 4 Aug 2021, Stefan Kanthak wrote:
>> The change just follows by removing 6 LOC/instructions.-)
> 
> Have you considered collecting the three bits in one go via a multiplication?

No. My mind is not that twisted;-)

> You can first isolate the necessary bits with 'and $0x4300, %eax', then do
> 'imul $0x910000, %eax, %eax' to put the required bits in EAX[31:29] in the
> right order, then shift right by 29. Three instructions, 14 bytes.

Thanks, VERY NICE! How did you come up to it?

Revised patch with shorter bit twiddling attached.

Stefan

[-- Attachment #2: remquo.patch --]
[-- Type: application/octet-stream, Size: 1073 bytes --]

--- -remquo.s
+++ +remquo.s
@@ -2,49 +2,41 @@
 .type remquof,@function
 remquof:
 	mov 12(%esp),%ecx
+	mov 8(%esp),%eax
+	xor 4(%esp),%eax
 	flds 8(%esp)
 	flds 4(%esp)
-	mov 11(%esp),%dh
-	xor 7(%esp),%dh
-	jmp 1f
+	jmp 0f
 
 .global remquol
 .type remquol,@function
 remquol:
 	mov 28(%esp),%ecx
+	mov 24(%esp),%eax
+	xor 12(%esp),%eax
+	cwtl
 	fldt 16(%esp)
 	fldt 4(%esp)
-	mov 25(%esp),%dh
-	xor 13(%esp),%dh
-	jmp 1f
+	jmp 0f
 
 .global remquo
 .type remquo,@function
 remquo:
 	mov 20(%esp),%ecx
+	mov 16(%esp),%eax
+	xor 8(%esp),%eax
 	fldl 12(%esp)
 	fldl 4(%esp)
-	mov 19(%esp),%dh
-	xor 11(%esp),%dh
+0:	cltd
 1:	fprem1
 	fnstsw %ax
 	sahf
 	jp 1b
 	fstp %st(1)
-	mov %ah,%dl
-	shr %dl
-	and $1,%dl
-	mov %ah,%al
-	shr $5,%al
-	and $2,%al
-	or %al,%dl
-	mov %ah,%al
-	shl $2,%al
-	and $4,%al
-	or %al,%dl
-	test %dh,%dh
-	jns 1f
-	neg %dl
-1:	movsbl %dl,%edx
-	mov %edx,(%ecx)
+	and $0x4300,%eax
+	imul $0x910000,%eax,%eax
+	shr $29,%eax
+	xor %edx,%eax
+	sub %edx,%eax
+	mov %eax,(%ecx)
 	ret