mailing list of musl libc
 help / color / mirror / code / Atom feed
85bb686c8820346f5885a900e3e11fbe2e0d6b89 blob 1132 bytes (raw)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
61
62
63
64
65
66
67
68
69
70
71
72
 
.global memset
.type memset,@function
memset:
	movzbq %sil,%rax
	mov $0x101010101010101,%r8
	imul %r8,%rax

	cmp $126,%rdx
	ja 2f

	test %edx,%edx
	jz 1f

	mov %sil,(%rdi)
	mov %sil,-1(%rdi,%rdx)
	cmp $2,%edx
	jbe 1f

	mov %ax,1(%rdi)
	mov %ax,(-1-2)(%rdi,%rdx)
	cmp $6,%edx
	jbe 1f

	mov %eax,(1+2)(%rdi)
	mov %eax,(-1-2-4)(%rdi,%rdx)
	cmp $14,%edx
	jbe 1f

	mov %rax,(1+2+4)(%rdi)
	mov %rax,(-1-2-4-8)(%rdi,%rdx)
	cmp $30,%edx
	jbe 1f

	mov %rax,(1+2+4+8)(%rdi)
	mov %rax,(1+2+4+8+8)(%rdi)
	mov %rax,(-1-2-4-8-16)(%rdi,%rdx)
	mov %rax,(-1-2-4-8-8)(%rdi,%rdx)
	cmp $62,%edx
	jbe 1f

	mov %rax,(1+2+4+8+16)(%rdi)
	mov %rax,(1+2+4+8+16+8)(%rdi)
	mov %rax,(1+2+4+8+16+16)(%rdi)
	mov %rax,(1+2+4+8+16+24)(%rdi)
	mov %rax,(-1-2-4-8-16-32)(%rdi,%rdx)
	mov %rax,(-1-2-4-8-16-24)(%rdi,%rdx)
	mov %rax,(-1-2-4-8-16-16)(%rdi,%rdx)
	mov %rax,(-1-2-4-8-16-8)(%rdi,%rdx)

1:	mov %rdi,%rax
	ret

2:	test $15,%edi
	mov %rdi,%r8
	mov %rax,-8(%rdi,%rdx)
	lea -1(%rdx),%rcx
	jnz 2f

1:	shr $3,%rcx
	rep
	stosq
	mov %r8,%rax
	ret

2:	xor %edx,%edx
	sub %edi,%edx
	and $15,%edx
	mov %rax,(%rdi)
	mov %rax,8(%rdi)
	sub %rdx,%rcx
	add %rdx,%rdi
	jmp 1b
debug log:

solving 85bb686c ...
found 85bb686c in https://inbox.vuxu.org/musl/20201003223209.10307-1-vda.linux@googlemail.com/
found 2d3f5e52 in https://git.vuxu.org/mirror/musl/
preparing index
index prepared:
100644 2d3f5e52b8afe8d612c0fd0b04f4e8a01f078489	src/string/x86_64/memset.s

applying [1/1] https://inbox.vuxu.org/musl/20201003223209.10307-1-vda.linux@googlemail.com/
diff --git a/src/string/x86_64/memset.s b/src/string/x86_64/memset.s
index 2d3f5e52..85bb686c 100644

Checking patch src/string/x86_64/memset.s...
Applied patch src/string/x86_64/memset.s cleanly.

index at:
100644 85bb686c8820346f5885a900e3e11fbe2e0d6b89	src/string/x86_64/memset.s

Code repositories for project(s) associated with this public inbox

	https://git.vuxu.org/mirror/musl/

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).