From: Alexander Monakov <amonakov@ispras.ru>
To: musl@lists.openwall.com
Subject: Re: sem_getvalue conformance considerations
Date: Mon, 1 Sep 2014 21:50:16 +0400 (MSK) [thread overview]
Message-ID: <alpine.LNX.2.00.1409012059290.1514@monopod.intra.ispras.ru> (raw)
In-Reply-To: <alpine.LNX.2.00.1408292251540.5292@monopod.intra.ispras.ru>
Hi,
If there's interest, my basic model file for semaphores in Promela/Spin is
pasted below. Perhaps if I started doing this earlier it would help to avoid
some mistakes.
// spin -a sem.pml && gcc -O2 -DSAFETY pan.c && ./a.out
typedef sem_t {
int value, waiters; // Behavior
int val0, val1; // Implementation
};
sem_t sem;
#define sem_invariants ( \
(sem.value >= 0 && sem.waiters >= 0) && \
(sem.value == 0 || sem.waiters == 0) && \
sem.val0 == sem.value - sem.waiters && \
sem.val1 >= 0)
bool done;
active proctype monitor()
{
do
:: d_step { !sem_invariants -> assert(0); }
:: done -> break;
od
}
inline sem_trywait(retval)
{
// d_step sequences are not preemptible
if
:: d_step { sem.val0 > 0 -> sem.val0--; sem.value--; retval = 0; }
:: else { retval = -1; }
fi
}
inline sem_post()
{
int v;
d_step {
v = sem.val0;
sem.val0++;
if
:: v >= 0 -> sem.value++;
:: v < 0 -> sem.waiters--;
fi
}
if
:: v < 0 -> sem.val1++;
:: else
fi
}
inline sem_wait(interruptible, retval)
{
int v;
d_step {
retval = 0;
v = sem.val0;
sem.val0--;
if
:: v > 0 -> sem.value--;
:: v <= 0 -> sem.waiters++;
fi
}
if
:: v <= 0 ->
if // non-deterministic if interruptible && sem.val1 > 0
:: d_step {sem.val1 > 0 -> sem.val1--;}
:: interruptible ->
d_step {
v = sem.val0;
if
:: v < 0 -> sem.val0++; sem.waiters--; retval = -1;
:: else
fi
}
if
:: v >= 0 -> d_step {sem.val1 > 0; sem.val1--;}
:: else
fi
fi
:: else
fi
}
int n_posts, n_waits, n_waitfails;
proctype waiter(bool interruptible)
{
int retval;
n_waits++;
sem_wait(interruptible, retval);
n_waitfails = n_waitfails - retval;
}
proctype poster()
{
n_posts++;
sem_post();
}
#define NPROCMAX 4
init
{
int n_procs = NPROCMAX;
do // start a non-deterministic amount of posters
:: n_procs > 0 -> run poster(); n_procs--;
:: 1 -> break;
od;
do // ditto for waiters
:: n_procs > 0 -> run waiter(false); n_procs--;
:: 1 -> break;
od;
do
:: n_procs > 0 -> run waiter(true); n_procs--;
:: 1 -> break;
od;
timeout; // wait until quiescent state
assert(sem.val1 == 0 && sem.val0 == n_posts + n_waitfails - n_waits);
n_procs = sem.waiters;
do
:: n_procs > 0 -> run poster(); n_procs--;
:: else -> break;
od;
timeout; // wait; there should be no processes except "monitor"
assert(sem.val1 == 0 && sem.val0 == n_posts + n_waitfails - n_waits);
assert(sem.waiters == 0);
done = true;
}
next prev parent reply other threads:[~2014-09-01 17:50 UTC|newest]
Thread overview: 19+ messages / expand[flat|nested] mbox.gz Atom feed top
2014-08-27 2:33 Rich Felker
2014-08-27 7:05 ` Jens Gustedt
2014-08-27 7:43 ` Rich Felker
2014-08-27 10:43 ` Alexander Monakov
2014-08-27 13:32 ` Alexander Monakov
2014-08-27 19:06 ` Alexander Monakov
2014-08-27 21:06 ` Alexander Monakov
2014-08-28 20:47 ` Alexander Monakov
2014-08-29 22:51 ` Alexander Monakov
2014-08-30 5:12 ` Rich Felker
2014-09-01 17:50 ` Alexander Monakov [this message]
2015-02-27 23:21 ` semaphore redesign Alexander Monakov
2015-02-28 15:42 ` Rich Felker
2015-03-01 18:54 ` Alexander Monakov
2015-03-01 17:30 ` Szabolcs Nagy
2015-03-01 17:50 ` Szabolcs Nagy
2015-03-02 22:40 ` Alexander Monakov
2015-03-02 22:45 ` Rich Felker
2015-03-01 18:24 ` Alexander Monakov
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=alpine.LNX.2.00.1409012059290.1514@monopod.intra.ispras.ru \
--to=amonakov@ispras.ru \
--cc=musl@lists.openwall.com \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/musl/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).