From mboxrd@z Thu Jan  1 00:00:00 1970
X-Msuck: nntp://news.gmane.io/gmane.comp.tex.context/7969
Path: main.gmane.org!not-for-mail
From: =?iso-8859-1?Q?Johannes_H=FCsing?= <hannes@ruhrau.de>
Newsgroups: gmane.comp.tex.context
Subject: Overlays that vary with page number
Date: Thu, 23 May 2002 06:17:32 +0200
Sender: owner-ntg-context@let.uu.nl
Message-ID: <20020523061732.B544@ruhrau.de>
Reply-To: johannes.huesing@ruhrau.de
NNTP-Posting-Host: coloc-standby.netfonds.no
Mime-Version: 1.0
Content-Type: text/plain; charset=iso-8859-1
Content-Transfer-Encoding: 8bit
X-Trace: main.gmane.org 1035398407 23817 80.91.224.250 (23 Oct 2002 18:40:07 GMT)
X-Complaints-To: usenet@main.gmane.org
NNTP-Posting-Date: Wed, 23 Oct 2002 18:40:07 +0000 (UTC)
Original-To: ntg-context@ntg.nl
Xref: main.gmane.org gmane.comp.tex.context:7969
X-Report-Spam: http://spam.gmane.org/gmane.comp.tex.context:7969

In the accompanying lines I have attempted to insert a graphic in the
footer that changes with every new page. While the graphic in the text 
adapts itself to roughly the page it sits on, the overlay in the footer
always stays the same. Why is that so, and how can this be remedied?

Greetings

Johannes

\setupoutput[pdftex]
\runMPgraphicstrue

\protectbufferstrue

\defineoverlay
  [test]
  [{\setupMPvariables[band][seite=\pagenumber,
    anzahlseiten=\totalnumberofpages]
    \useMPgraphic{band}}]

\setupbackgrounds
  [footer]
  [background=test]

\startuseMPgraphic{band}

def norm(expr a) =
xpart(a)++ypart(a)
enddef;

def cctangent(expr rs, rr, zs, zr, d) =
  pair ts, tr;
  alpha := angle((norm(zs-zr), rs-rr));
  beta := angle(zs-zr);

  ts := zs + (0, d*rs) rotated (beta+(d*alpha));
  tr := zr + (0, d*rr) rotated (beta+(d*alpha));

  draw ts--tr;
enddef ;

pair z_rspule, z_rrolle, t_rspule, t_rrolle,
     z_lspule, z_lrolle, t_lspule, t_lrolle;
numeric a_lwick, a_rwick, r_lwick, r_rwick;

LoadPageState;
zeit := 45*PageNumber/(NOfPages+1);  % Zeit in Minuten (0-45) auf einer C90
% zeit := \MPvar{seite}/\MPvar{anzahlseiten}*45;  % Zeit in Minuten (0-45) auf einer C90

u := 2pt;                % Maßeinheit
r_lspule := 2u;          % Radius der linken Spule
r_rspule := r_lspule;    % Radius der rechten Spule
r_lrolle := 1u;          % Radius der linken Rolle
r_rrolle := 1u;          % Radius der rechten Rolle
z_lspule := (-10u,10u);  % Mittelpunkt der linken Spule
z_rspule := ( 10u,10u);  % Mittelpunkt der rechten Spule
z_lrolle := (-15u,0u);   % Mittelpunkt der linken Rolle
z_rrolle := ( 15u,0u);   % Mittelpunkt der rechten Rolle

% label.top(decimal zeit, z_lspule);

%  Die Stärke der Wicklung wird folgendermaßen berechnet:
%  Die Zeit ist proportional zur Fläche, die Fläche ist
%  das Quadrat des Durchmessers minus dem Quadrat des
%  Durchmessers der Spule.

geswick := 450;           % Gesamtfläche der Wicklung auf den Spulen
geszeit := 45;            % Gesamtspieldauer

a_lwick + a_rwick = geswick;
a_lwick = geswick*zeit/geszeit;

r_lwick = sqrt(a_lwick+(r_lspule*r_lspule));
r_rwick = sqrt(a_rwick+(r_rspule*r_rspule));

%  Zeichne gewickeltes Band auf beiden Spulen, nimm
%  Spulen wieder aus. Zeichne Umlenkrollen.

fill fullcircle scaled (2*r_lwick) shifted z_lspule ;
unfill fullcircle scaled (2*r_lspule) shifted z_lspule ;
draw fullcircle scaled (2*r_lrolle) shifted z_lrolle ;
fill fullcircle scaled (2*r_rwick) shifted z_rspule ;
unfill fullcircle scaled (2*r_rspule) shifted z_rspule ;
draw fullcircle scaled (2*r_rrolle) shifted z_rrolle ;

%  Zeichne Band zwischen Spulen und Rollen.

cctangent(r_lwick, r_lrolle, z_lspule, z_lrolle, 1);
cctangent(r_rwick, r_rrolle, z_rspule, z_rrolle, -1);

%  Zeichne Band zwischen den beiden Rollen.

cctangent(r_rrolle, r_lrolle, z_rrolle, z_lrolle, -1);
% cstangent(r_rrolle, r_lrolle, z_rrolle, z_lrolle);
\stopuseMPgraphic

\starttext

\dorecurse{20}{%
  \input tufte \par
  \setupMPvariables[band][seite=\pagenumber,
                          anzahlseiten=\totalnumberofpages]
  \inmargin{\useMPgraphic{band}}}

\stoptext

-- 
Johannes Hüsing   There is something fascinating about science. One gets
hannes@ruhrau.de  such wholesale returns of conjecture from such a 
                  trifling investment of fact.                Mark Twain