Re: A Metapost need

Re: A Metapost need

[Hans Hagen]

[-- Attachment #1: Type: text/plain, Size: 2693 bytes --]

At 08:41 PM 11/29/00 -0800, David Arnold wrote:
>Hans,
>
>When mathematicians draw parametric curves, they frequently need to
>indicate the direction of motion. I often have need of a little macro that
>will put an arrow of requested length, anchored at a point on the curve,
>and bending with the curve in the direction of motion. 
>
>I am looking for a nice way to do this. Got any ideas?

Well, you expressed the idea already, so you need the implementation -) 

If there are more of such general wishes, I can consider adding the
solutions to the new metafun macros [bunch of mp and tex]  to be released
soon. Don't expect too much and too clever macros. 

================= code ===================================

% output=pdftex

\setupcolors[state=start]

\setuplayout[width=middle,height=middle]

\starttext 

\startbuffer[macros]
\startMPinclusions
vardef pointarrow (expr pat, loc, len, off) =
  save l, r, s ; path l, r ; numeric s ; 
% draw loc withpen pencircle scaled 10 withcolor .5white ; 
  s := len/2 - off ; if s<=0 : s := 0 elseif s>len : s := len fi ;  
  r := pat cutbefore loc ;
  r := (r cutafter point (arctime s of r) of r) ;
  s := len/2 + off ; if s<=0 : s := 0 elseif s>len : s := len fi ;  
  l := reverse (pat cutafter loc) ;
  l := (reverse (l cutafter point (arctime s of l) of l)) ;
  (l..r) 
enddef ; 

def rightarrow  (expr pat,tim,len) = pointarrow(pat,tim,len,-len) enddef ; 
def leftarrow   (expr pat,tim,len) = pointarrow(pat,tim,len,+len) enddef ; 
def centerarrow (expr pat,tim,len) = pointarrow(pat,tim,len,   0) enddef ;
\stopMPinclusions
\stopbuffer

\getbuffer[macros]

\startbuffer
\startMPcode
  pickup pencircle scaled 2pt; 

  path p ; p := fullcircle scaled 5cm ; draw p ; 

  for i=1,3,5,7 : 
    drawdot point i of p withpen pencircle scaled 10 withcolor .5white ; 
  endfor ; 

  drawarrow leftarrow   (p,point 1 of p,1cm)      withcolor red    ; 
  drawarrow rightarrow  (p,point 3 of p,1cm)      withcolor green  ; 
  drawarrow centerarrow (p,point 5 of p,1cm)      withcolor blue   ;  
  drawarrow pointarrow  (p,point 7 of p,2cm,.5cm) withcolor yellow ;
\stopMPcode
\stopbuffer

The following code will produce small arrows positioned at a
given location with a given length and optional shift. 

\typebuffer

The shift of .5cm in the last example (the yellow arrow) is 
a backward shift. This may be fuzzy, but negative values 
would be even more confusing. By default the arrow is 
centered around the given point. 

\startlinecorrection[blank]
\getbuffer
\stoplinecorrection

The code that produces the arrow is (here) defined as 
inclusion, but may end up it in the \MetaFun\ macro 
collection. 

\typebuffer[macros]

\stoptext 

[-- Attachment #2: a.pdf --]
[-- Type: application/pdf, Size: 25716 bytes --]

[-- Attachment #3: Type: text/plain, Size: 370 bytes --]

-------------------------------------------------------------------------
                                                  Hans Hagen | PRAGMA ADE
                      Ridderstraat 27 | 8061 GH Hasselt | The Netherlands
 tel: +31 (0)38 477 53 69 | fax: +31 (0)38 477 53 74 | www.pragma-ade.com
-------------------------------------------------------------------------