Re: Write once layout everwhere (?)

From: nico <nicolas.marsgui@libertysurf.fr>
To: "mailing list for ConTeXt users" <ntg-context@ntg.nl>
Subject: Re: Write once layout everwhere (?)
Date: Mon, 11 Jun 2007 21:35:52 +0200	[thread overview]
Message-ID: <opttrvd2rn9niby6@localhost> (raw)
In-Reply-To: <20070611114223.uig799728080wows@web.mail.umich.edu>

[-- Attachment #1: Type: text/plain, Size: 1298 bytes --]

On Mon, 11 Jun 2007 11:42:23 -0400, Aditya Mahajan <adityam@umich.edu>  
wrote:

> Thanks. I had not looked at them and some of the things about handling
> at the ConTeXt end are more clear now. But I think that I did not
> explain my question correctly.
>
> What I do not understand how are abbreviations etc. handled by xslt for
> conversion into html. For example, how do I write an xsl style sheet
> that converts this xml input
>
> <abbreviation value="EECS", short="EECS", full="Electrical Engineering
> and Computer Science" />
>
> <p> I study <abbrev value="EECS"> which stands for <abbrev
> value="EECS", infull="yes"> </p>
>
> into html as
>
> <p> I study EECS which stands for Electrical Engineering and Computer
> Science </p>
>
> I know that this is not the right list to ask this sort of questions,
> but I am hoping that there are xml users here and they will be able to
> point me to the right direction.

I haven't followed the thread, but attached an idea of doing what you want  
with XSLT. Note that your example is not valid at all (commas between  
attributes, missing ending '/' for empty elements). BTW, it's not a good  
idea to use the same attribute ("value") as an reference identifier, and  
for referencing to another element.

Regards,

[-- Attachment #2: myxsl.xsl --]
[-- Type: application/octet-stream, Size: 1063 bytes --]

<?xml version='1.0'?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version='1.0'>

<xsl:output method="html" encoding="UTF-8" indent="yes"/>

<xsl:template match="abbrev">
  <xsl:variable name="abbrev" select="//abbreviation[@value=current()/@value]"/>
  <xsl:if test="$abbrev">
    <xsl:apply-templates select="$abbrev" mode="short"/>
  </xsl:if>
</xsl:template>

<xsl:template match="abbrev[@infull='yes']">
  <xsl:variable name="abbrev" select="//abbreviation[@value=current()/@value]"/>
  <xsl:if test="$abbrev">
    <xsl:apply-templates select="$abbrev" mode="full"/>
  </xsl:if>
</xsl:template>

<xsl:template match="abbreviation"/>

<xsl:template match="abbreviation" mode="full">
  <xsl:value-of select="@full"/>
</xsl:template>

<xsl:template match="abbreviation" mode="short">
  <xsl:value-of select="@short"/>
</xsl:template>

<xsl:template match="p">
  <p>
  <xsl:apply-templates/>
  </p>
</xsl:template>

<xsl:template match="/">
  <xsl:apply-templates/>
</xsl:template>

</xsl:stylesheet>

[-- Warning: decoded text below may be mangled, UTF-8 assumed --]
[-- Attachment #3: myfile.xml --]
[-- Type: text/xml; name=myfile.xml, Size: 228 bytes --]

<body>
<abbreviation value="EECS" short="EECS"
              full="Electrical Engineering and Computer Science" />

<p> I study <abbrev value="EECS"/> which stands for <abbrev 
value="EECS" infull="yes"/> </p>

</body>

[-- Attachment #4: Type: text/plain, Size: 487 bytes --]

___________________________________________________________________________________
If your question is of interest to others as well, please add an entry to the Wiki!

maillist : ntg-context@ntg.nl / http://www.ntg.nl/mailman/listinfo/ntg-context
webpage  : http://www.pragma-ade.nl / http://tex.aanhet.net
archive  : https://foundry.supelec.fr/projects/contextrev/
wiki     : http://contextgarden.net
___________________________________________________________________________________