Re: autoconfig

[Chet Ramey <chet@odin.INS.CWRU.Edu>]

> I am sorely tempted to remove named pipe support. It never worked
> properly. So something is needed to auto-sense the particular
> encoding for /dev/fd (systems encode this differently), which I
> doubt is supplied by GNU autoconf.

Here is the test from bash's aclocal.m4 (the `local extensions' to
autoconf).  It handles /dev/fd and Linux's whacky /proc/self/fd, and it
is easy enough to add more directory prefixes to the check.  The bash
code then checks whether a file in /dev/fd is specified and constructs
the pathname to use with DEV_FD_PREFIX.  The bash `test' code and the
code that builds filenames for use in process substitution both use
DEV_FD_PREFIX when HAVE_DEV_FD is defined.

AC_DEFUN(BASH_CHECK_DEV_FD,
[AC_MSG_CHECKING(whether /dev/fd is available)
AC_CACHE_VAL(bash_cv_dev_fd,
[if test -d /dev/fd  && test -r /dev/fd/0; then
   bash_cv_dev_fd=standard
 elif test -d /proc/self/fd && test -r /proc/self/fd/0; then
   bash_cv_dev_fd=whacky
 else
   bash_cv_dev_fd=absent
 fi
])
AC_MSG_RESULT($bash_cv_dev_fd)
if test $bash_cv_dev_fd = "standard"; then
  AC_DEFINE(HAVE_DEV_FD)
  AC_DEFINE(DEV_FD_PREFIX, "/dev/fd/")
elif test $bash_cv_dev_fd = "whacky"; then
  AC_DEFINE(HAVE_DEV_FD)
  AC_DEFINE(DEV_FD_PREFIX, "/proc/self/fd/")
fi
])

-- 
``The lyf so short, the craft so long to lerne.'' - Chaucer

Chet Ramey, Case Western Reserve University	Internet: chet@po.CWRU.Edu