From: Bart Schaefer <schaefer@brasslantern.com>
To: ZSH Users <zsh-users@sunsite.dk>
Subject: Re: Keying arrays to names: is there an array of arrays?
Date: Sun, 28 May 2006 11:17:24 -0700 [thread overview]
Message-ID: <060528111724.ZM29224@torch.brasslantern.com> (raw)
In-Reply-To: <m3ejyeg9nh.fsf@jin.myrkraverk.com>
On May 28, 2:34am, Johann 'Myrkraverk' Oskarsson wrote:
>
> The following version also works with IFS="" (I guess it will work
> with IFS equal to something sensible too).
>
> mapassign() {
> local h=$1 k=$2
> shift 2
> set -- ${(j: :q)*}
> typeset -gA $h
> typeset -g $h\[$k\]="$*"
> }
A better approach might be:
mapassign() {
emulate -L zsh
local h=$1 k=$2 IFS=$' \t\n\0'
shift 2
set -- ${(q)*}
typeset -gA $h
typeset -g $h\[$k\]="$*"
}
> Same with this one:
>
> mapread() {
> set -- $1\[$2\]
> reply=( ${(s: :Q)${(z)${(P)1}}} )
> }
That's actually incorrect. The (z) option is already splitting the
value; you shouldn't need or want to split it again with (s: :). If
the setting of IFS is preventing (z) from working properly, that's
probably a bug, but in any case the workaround is to make IFS local.
mapread() {
emulate -L zsh
local IFS=$' \t\n\0'
set -- $1\[$2\]
reply=( ${(Q)${(z)${(P)1}}} )
}
If you're going to use these functions for hash access anyway, then
you might as well also use ${(q)2} instead of $2 in both of them, to
avoid issues with non-alphanumeric keys.
next prev parent reply other threads:[~2006-05-28 18:17 UTC|newest]
Thread overview: 9+ messages / expand[flat|nested] mbox.gz Atom feed top
2006-05-26 14:20 Johann 'Myrkraverk' Oskarsson
2006-05-26 15:26 ` Marc Chantreux
2006-05-26 15:40 ` Peter Stephenson
2006-05-26 15:58 ` Peter Stephenson
2006-05-27 19:09 ` Johann 'Myrkraverk' Oskarsson
2006-05-27 22:10 ` Bart Schaefer
2006-05-28 2:34 ` Johann 'Myrkraverk' Oskarsson
2006-05-28 18:17 ` Bart Schaefer [this message]
2006-05-28 21:32 ` Johann 'Myrkraverk' Oskarsson
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=060528111724.ZM29224@torch.brasslantern.com \
--to=schaefer@brasslantern.com \
--cc=zsh-users@sunsite.dk \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).