how to search for a substring in a parameter?

how to search for a substring in a parameter?

[Carlos Carvalho]

I'm trying to see if the value of a parameter contains a given string
but didn't find an elegant way. All pattern matching substitutions
return only the non-matched portion of the value. There's a way to do
substitutions but not testing. I must be missing something. I'm using

   if (( ${#foo//pattern/} < ${#foo} )); then
	# contains pattern
   else
	# doesn't contain pattern
   fi

Is there a better way?

Re: how to search for a substring in a parameter?

[Bart Schaefer]

On Jan 13,  4:13pm, Carlos Carvalho wrote:
}
} I'm trying to see if the value of a parameter contains a given string

The right-hand-side of == in a [[ ]] construct is a glob pattern, so if
all you want is true/false, this works:

    if [[ $foo == *pattern* ]]; then
 	# contains pattern
    else
 	# doesn't contain pattern
    fi

If you want to extract the matching string, see the M and S flags:

    matching=${(SM)foo##pattern}

Re: how to search for a substring in a parameter?

[Zefram]

Carlos Carvalho wrote:
>I'm trying to see if the value of a parameter contains a given string
>but didn't find an elegant way.

	if [[ $parameter == *given_string* ]]; then
		# yes
	else
		# no
	fi

-zefram

Re: how to search for a substring in a parameter?

[Peter Stephenson]

Carlos Carvalho wrote:
> I'm trying to see if the value of a parameter contains a given string
> but didn't find an elegant way.

What was wrong with

if [[ $foo = *pattern* ]]; then
  ...

?  The patterns are identical to those in parameter substitution.

> All pattern matching substitutions
> return only the non-matched portion of the value.

You can use the flags M for the matched portion combined with either
head or tail matching using the S flag to tell it to match substrings,
i.e. anywhere in the pattern.

% foo='this is a pattern, too'
% print ${(MS)foo##pattern}
pattern

The M flag doesn't work with the `/' or `//' substitutions (and the S
flag is differnt --- it forces the shortest match).  Not clear
if that's `really' a bug, but it does agree with the documentation.

-- 
Peter Stephenson <pws@csr.com>                  Software Engineer
CSR Ltd., Science Park, Milton Road,
Cambridge, CB4 0WH, UK                          Tel: +44 (0)1223 692070


**********************************************************************
The information transmitted is intended only for the person or
entity to which it is addressed and may contain confidential 
and/or privileged material. 
Any review, retransmission, dissemination or other use of, or
taking of any action in reliance upon, this information by 
persons or entities other than the intended recipient is 
prohibited.  
If you received this in error, please contact the sender and 
delete the material from any computer.
**********************************************************************

Re: how to search for a substring in a parameter?

[Carlos Carvalho]

Sorry for making noise with such an easy question... I even found the
answer myself some time later but you were too fast in answering for
me to tell it. Anyway I now understand the meaning of M, thanks.

Fascinated by that part of the man page I tried the following:

% max=8
% bar=5
% if [[ $bar == <1-$max> ]] {print in } else {print out}
zsh: parse error: condition expected: $bar

It works if I change $max by 8. Is it illegal to have parameters
inside <-> or I'm doing it wrong? The man page is a little ambiguous.

Re: how to search for a substring in a parameter?

[Bart Schaefer]

On Jan 13,  7:48pm, Carlos Carvalho wrote:
}
} % if [[ $bar == <1-$max> ]] {print in } else {print out}
} zsh: parse error: condition expected: $bar
} 
} Is it illegal to have parameters inside <-> ...?

Yes.  Do it this way:

range='<1-8>'

if [[ $bar == ${~range} ]] {print in} else {print out}