Re: Is this the Zsh way for doing this?

[Bart Schaefer <schaefer@brasslantern.com>]

On Mar 25, 11:35pm, DervishD wrote:
}
} tail +2 .CDinfo | while read song

This is fine, but you might prefer the more obvious:

tail +2 .CDinfo | while read ignored_word track_number track_name
do
    # At this point ignored_word is always "Track" and track_number
    # still has a trailing colon that we need to strip off.  Also
    # track_name contains single quotes, but based on this example:
    #    Track 10: 'This song really doesn't exist...'
    # they aren't balanced single quotes, so we have to strip them.
    # If the zero-padding gets done here too, it's clearer later.
    track_number=${(l.2..0.)${track_number%:}}
    track_name=${${track_name%\'}#\'}

    # At this point you might also want to clean wildcards and slashes
    # out of $track_name, but that's up to you.  Your original doesn't.

    # Now the "mv" command is quite obvious.
    mv audio_${track_number}.cdr "${track_number}.${track_name}.cdr"
done

If you really desperately want to write it all as one command rather
than have the two extra assignments:

    mv  audio_${track_number/

As to your specific pattern-matching questions:

}     ${song/#(#b)Track #([0-9]##):'(*)'/${(l.2..0.)match[1]}.${match[2]}}.cdr
} 
} AFAIK, when pattern matching takes place
} at the point of the "'(*)'", it is implicitly anchored to the end of
} the string and is the longest match

No, it's not implicitly anchored at the end, but it is the longest match,
which (since there is always a single-quote at the end of the string) is
equivalent in this case.

However, you do need to escape the single quotes, and there is a space
after the colon:

	(#b)Track #([0-9]##): \'(*)\'

} [Why can't I] use the (#b) flag before the '/' (together with 'song')
} or before the '#' (which indicates that 'Track' must match at the
} beginning of the string) [...?]

What you've asked is very similar to asking about C,

    Why can't I put the "--" before the "+" or before the "=" in
    the expression "song += --pattern" ?

This is because the / and the # together constitute an operator on the
value of the variable, whereas (#b) is part of the pattern which is an
argument to that operator.

} BTW, is that '#' necessary or not?

It's not necessary as long as none of the names is "The Track 27: song"
or some such.

} Do I need to specify too the end of the string anchor?

No.