From: Bart Schaefer <schaefer@brasslantern.com>
To: zsh-users@zsh.org
Subject: Re: pure zsh implementation of wget
Date: Sat, 24 Sep 2011 14:42:46 -0700 [thread overview]
Message-ID: <110924144246.ZM25537@torch.brasslantern.com> (raw)
In-Reply-To: <1316895804.27230.YahooMailClassic@web65605.mail.ac4.yahoo.com>
On Sep 24, 1:23pm, Guido van Steen wrote:
}
} Now hopefully my last question: is there an easy way to get rid of the
} first part of the file
That's just the standard header in the HTTP format, like the header on
an email message. You just have to discard everything up to the first
blank line.
One other thing you may want to do is switch from 'HTTP/1.1' to 1.0 to
prevent the server from breaking the content into chunks. You'll be
limited to 10MB downloads but won't have to interpret any content after
the first blank line.
A blank line here means one matching $'\015\012', but "read" will strip
the $'\012' so:
zwget() {
emulate -LR zsh
local scheme empty server resource fd headerline
IFS=/ read scheme empty server resource <<<$1
case $scheme in
(https:) print -u2 SSL unsupported, falling back on HTTP ;&
(http:)
zmodload zsh/net/tcp
ztcp $server 80 && fd=$REPLY || return 1;;
(*) print -u2 $scheme unsupported; return 1;;
esac
print -l -u$fd -- \
"GET /$resource HTTP/1.0"$'\015' \
"Host: $server"$'\015' \
'Connection: close'$'\015' $'\015'
while IFS= read -u $fd -r headerline
do
[[ $headerline == $'\015' ]] && break
done
while IFS= read -u $fd -r -e; do :; done
ztcp -c $fd
}
next prev parent reply other threads:[~2011-09-24 21:42 UTC|newest]
Thread overview: 16+ messages / expand[flat|nested] mbox.gz Atom feed top
2011-09-22 21:06 Guido van Steen
2011-09-22 21:50 ` Mikael Magnusson
2011-09-23 5:23 ` Guido van Steen
2011-09-23 6:57 ` Mikael Magnusson
2011-09-23 7:13 ` Guido van Steen
2011-09-23 12:06 ` Guillaume Brunerie
2011-09-23 12:12 ` İsmail Dönmez
2011-09-23 7:01 ` Bart Schaefer
2011-09-23 7:16 ` Guido van Steen
2011-09-27 9:02 ` Oliver Kiddle
2011-09-24 16:49 ` Guido van Steen
2011-09-24 17:58 ` Bart Schaefer
2011-09-24 20:23 ` Guido van Steen
2011-09-24 21:11 ` Guido van Steen
2011-09-24 21:42 ` Bart Schaefer [this message]
2011-09-22 21:53 ` Stephane Bortzmeyer
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=110924144246.ZM25537@torch.brasslantern.com \
--to=schaefer@brasslantern.com \
--cc=zsh-users@zsh.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).