spell check on the command line

spell check on the command line

[Eric Smith]

Dear zshellers

I make frequent typos (which I like to blame on my apple
keyboard). These are either in commands themselves or in long
filenames concatenated with underscores as arguments to commands.

(Of course autocorrect in a command could be dangerous, but then
so could a typo).

But especially interesting is a spell check for my
long_filenames_with_useful_tags_as_metadata.pdf

How could I implement and autocorrect function that is run when I
press enter and on suspected spell error beeps and
guesses what I meant and would give me a chance to review the
correction?

-- 
Eric Smith

Re: spell check on the command line

[Bart Schaefer]

On Oct 24, 12:54pm, Eric Smith wrote:
}
} How could I implement and autocorrect function that is run when I
} press enter and on suspected spell error beeps and
} guesses what I meant and would give me a chance to review the
} correction?

Have you tried

	setopt CORRECT_ALL

??  If so, what does it not do that you want done differently?

Re: spell check on the command line

[Eric Smith]

Thanks Bart

Bart Schaefer wrote on Fri-24-Oct 14  5:36PM
> On Oct 24, 12:54pm, Eric Smith wrote:
> Have you tried
> 
> 	setopt CORRECT_ALL
> 
> ??  If so, what does it not do that you want done differently?

~>  setopt CORRECTALL
~> cat /ettc/issue
zsh: correct '/ettc/issue' to '/etc/issue' [nyae]? y
Ubuntu 14.04.1 LTS \n \l

~> touch this_settting_doess_not_yet_check_the_spelling_of_these_tags_in_a_filename.txt
~> 

-- 
Eric Smith

Re: spell check on the command line

[Bart Schaefer]

On Oct 24, 11:19pm, Eric Smith wrote:
}
} ~> setopt CORRECTALL
} ~> touch this_settting_doess_not_yet_check_the_spelling_of_these_tags_in_a_filename.txt

Oh, so you want a regular spelling dictionary applied in some way, to
substrings within each command-line argument.  Or perhaps only to
substrings within file names, but since it's not possible to tell in
general which arguments are file names (a shortcoming correctall has
already), it's effectively the same problem.

Let's ignore the complications of shell keywords like "elif", complex
commands like loops, and multi-line buffers.  Your basic choices are:

- override the accept-line widget; or
- create (or add to if already using one) a zle-line-finish widget; or
- attempt to handle it all in prexec.

The simplest one is zle-line-finish so I'll do a quick example of that
here.  If you do it in preexec it's more difficult to implement the
(a)bort and (e)dit cases.

I'll assume that anything matching [[:punct:]] is taken as a word break,
and also that a program or function "suggest" exists that will spit out
pairs of wrong words and their replacments (unlike "spell" which emits
only the wrong words).

    zle-line-finish() {
      local spelt misspelt nyae
      print -R ${BUFFER//[[:punct:][:digit:]]/$'\n'} | suggest |
      while read misspelt spelt
      do
	read -k 1 nyae$'?\n'"correct '$misspelt' to '$spelt' [nyae]? "
	case ${nyae:l} in
	(a) zle send-break;;
	(e) zle push-line; return;;
	(y) BUFFER=${BUFFER/$misspelt/$spelt};;
	esac
        [[ -n $nyae ]] && print -nR $nyae
      done
      [[ -n $nyae ]] && { print; zle redisplay }
    }
    zle -N zle-line-finish

Use at your own risk.

Re: spell check on the command line

[Eric Smith]

Looks great Bart, thank you!

I cannot find the application "suggest" anywhere, what do you
suggest?

Eric

Bart Schaefer wrote on Sat-25-Oct 14  9:24AM
> On Oct 24, 11:19pm, Eric Smith wrote:
> }
> } ~> setopt CORRECTALL
> } ~> touch this_settting_doess_not_yet_check_the_spelling_of_these_tags_in_a_filename.txt
> 
> Oh, so you want a regular spelling dictionary applied in some way, to
> substrings within each command-line argument.  Or perhaps only to
> substrings within file names, but since it's not possible to tell in
> general which arguments are file names (a shortcoming correctall has
> already), it's effectively the same problem.
> 
> Let's ignore the complications of shell keywords like "elif", complex
> commands like loops, and multi-line buffers.  Your basic choices are:
> 
> - override the accept-line widget; or
> - create (or add to if already using one) a zle-line-finish widget; or
> - attempt to handle it all in prexec.
> 
> The simplest one is zle-line-finish so I'll do a quick example of that
> here.  If you do it in preexec it's more difficult to implement the
> (a)bort and (e)dit cases.
> 
> I'll assume that anything matching [[:punct:]] is taken as a word break,
> and also that a program or function "suggest" exists that will spit out
> pairs of wrong words and their replacments (unlike "spell" which emits
> only the wrong words).
> 
>     zle-line-finish() {
>       local spelt misspelt nyae
>       print -R ${BUFFER//[[:punct:][:digit:]]/$'\n'} | suggest |
>       while read misspelt spelt
>       do
> 	read -k 1 nyae$'?\n'"correct '$misspelt' to '$spelt' [nyae]? "
> 	case ${nyae:l} in
> 	(a) zle send-break;;
> 	(e) zle push-line; return;;
> 	(y) BUFFER=${BUFFER/$misspelt/$spelt};;
> 	esac
>         [[ -n $nyae ]] && print -nR $nyae
>       done
>       [[ -n $nyae ]] && { print; zle redisplay }
>     }
>     zle -N zle-line-finish
> 
> Use at your own risk.

-- 
Eric Smith

Re: spell check on the command line

[Bart Schaefer]

On Oct 25, 10:17am, Eric Smith wrote:
}
} I cannot find the application "suggest" anywhere, what do you
} suggest?

No pun intended?

If you have ispell or aspell you can run them with the -a option and
parse the output.  I'm sure there's a way to do the same with hunspell
but I'm not familiar with the details.

It'd be something like

  suggest() {
    local tag misspelt count offset suggestions
    aspell -a |
    while read tag misspelt count offset suggestions
    do 
      [[ $tag = \& ]] && print -R $misspelt ${${(s:, :)suggestions}[1]}
    done
  }

Beware that aspell might suggest that a word be split into two words,
rather than corrected to a different single word, so you probably want
to adjust the above to filter ${(s:, :)suggestions} before deciding
which one to print.

-- 
Barton E. Schaefer

Re: spell check on the command line

[Eric Smith]

Thanks Bart.

All works first time.
(Perhaps one day I will actually become literate and learn to spell, perhaps not?)

ciao

Eric Smith

Bart Schaefer wrote on Sat-25-Oct 14  8:06PM
> On Oct 25, 10:17am, Eric Smith wrote:
> }
> } I cannot find the application "suggest" anywhere, what do you
> } suggest?
> 
> No pun intended?
> 
> If you have ispell or aspell you can run them with the -a option and
> parse the output.  I'm sure there's a way to do the same with hunspell
> but I'm not familiar with the details.
> 
> It'd be something like
> 
>   suggest() {
>     local tag misspelt count offset suggestions
>     aspell -a |
>     while read tag misspelt count offset suggestions
>     do 
>       [[ $tag = \& ]] && print -R $misspelt ${${(s:, :)suggestions}[1]}
>     done
>   }
> 
> Beware that aspell might suggest that a word be split into two words,
> rather than corrected to a different single word, so you probably want
> to adjust the above to filter ${(s:, :)suggestions} before deciding
> which one to print.
> 
> -- 
> Barton E. Schaefer

-- 
Eric Smith