zsh-users
 help / color / mirror / code / Atom feed
From: Zefram <zefram@tao.co.uk>
To: luomat+Lists/Zsh/users@luomat.peak.org (Timothy J Luoma)
Cc: zsh-users@math.gatech.edu
Subject: Re: help with 'rename' function
Date: Fri, 12 Jun 1998 10:26:15 +0100 (BST)	[thread overview]
Message-ID: <199806120926.KAA09704@taos.demon.co.uk> (raw)
In-Reply-To: <199806120816.EAA22173@luomat.peak.org> from "Timothy J Luoma" at Jun 12, 98 04:15:57 am

Timothy J Luoma wrote:
>You would do
>
>	rename *.THIS THIS=THAT

function rename {
	emulate zsh
	setopt localoptions
	integer st=0
	local pat old new f
	if (( $# < 2 )) || { pat=$argv[$#]; [[ $pat != *\=* ]]; }; then
		echo >&2 "Usage: rename <files...> <foo>=<bar>"
		return 2
	fi
	old=${pat%%\=*}
	new=${pat#*\=}
	for f in $argv[1,-2]; do
		if [[ $f != *$old ]]; then
			st=1
			echo >&2 "$f: does not end with suffix \`$old'"
		elif ! mv $f ${f%$old}$new; then
			st=1
		fi
	done
	return $st
}

If you use the files module, then this function does not use any external
commands.

-zefram


  parent reply	other threads:[~1998-06-12  9:31 UTC|newest]

Thread overview: 11+ messages / expand[flat|nested]  mbox.gz  Atom feed  top
1998-06-12  8:15 Timothy J Luoma
1998-06-12  9:09 ` Peter Stephenson
1998-06-14 20:05   ` Paul Lew
1998-06-12  9:14 ` Bart Schaefer
1998-06-12  9:26 ` Zefram [this message]
1998-06-12  9:55 ` Hannu Koivisto
1998-06-12 23:07 ` Thomas Köhler
1998-06-13 11:02   ` rename THIS=THAT Sven Guckes
     [not found]     ` <Pine.SOL.3.95.980613090415.15614A-100000@x139-110.med.umn.edu>
1998-06-15  0:37       ` zsh - rename THIS=THAT - mv $a $a:s/THIS/THAT/ Sven Guckes
     [not found] <Pine.SOL.3.95.980612084320.12190A-100000@x139-110.med.umn.edu>
1998-06-12 15:53 ` help with 'rename' function Timothy J Luoma
1998-06-12 16:21   ` Geoff Wing

Reply instructions:

You may reply publicly to this message via plain-text email
using any one of the following methods:

* Save the following mbox file, import it into your mail client,
  and reply-to-all from there: mbox

  Avoid top-posting and favor interleaved quoting:
  https://en.wikipedia.org/wiki/Posting_style#Interleaved_style

* Reply using the --to, --cc, and --in-reply-to
  switches of git-send-email(1):

  git send-email \
    --in-reply-to=199806120926.KAA09704@taos.demon.co.uk \
    --to=zefram@tao.co.uk \
    --cc=luomat+Lists/Zsh/users@luomat.peak.org \
    --cc=zsh-users@math.gatech.edu \
    /path/to/YOUR_REPLY

  https://kernel.org/pub/software/scm/git/docs/git-send-email.html

* If your mail client supports setting the In-Reply-To header
  via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line before the message body. 
Code repositories for project(s) associated with this public inbox

	https://git.vuxu.org/mirror/zsh/

This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).