1ff7630fb81e8fbcdbdfe24e7fe103fd695073b3 blob 1027 bytes (raw)
1
2
3
4
5
6
7
8
9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
| | #compdef -k complete-word \C-x?
eval "$_comp_setup"
(( $+_debug_count )) || integer -g _debug_count
local tmp=${TMPPREFIX}${$}${words[1]:t}$[++_debug_count]
local pager w="${(qq)words}"
integer debug_fd=-1
{
if [[ -t 2 ]]; then
zmodload -F zsh/files b:zf_ln 2>/dev/null &&
zf_ln -fn =(<<<'') $tmp &&
exec {debug_fd}>&2 2>| $tmp
fi
local -a debug_indent; debug_indent=( '%'{3..20}'(e. .)' )
local PROMPT4 PS4="${(j::)debug_indent}+%D{%S.%.}:%N:%i> "
setopt xtrace
: $ZSH_NAME $ZSH_VERSION
${1:-_main_complete}
integer ret=$?
unsetopt xtrace
if (( debug_fd != -1 )); then
zstyle -s ':completion:complete-debug::::' pager pager
print -sR "${pager:-${PAGER:-${VISUAL:-${EDITOR:-more}}}} ${(q)tmp} ;: $w"
_message -r "Trace output left in $tmp (up-history to view)"
if [[ $compstate[nmatches] -le 1 && $compstate[list] != *force* ]]; then
compstate[list]='list force messages'
fi
fi
} always {
(( debug_fd != -1 )) && exec 2>&$debug_fd {debug_fd}>&-
}
return ret
|
debug log:
solving 1ff7630 ...
found 1ff7630 in https://inbox.vuxu.org/zsh-users/20180418135817.7edca58c@camnpupstephen.cam.scsc.local/
found 85a0f37 in https://git.vuxu.org/mirror/zsh/
preparing index
index prepared:
100644 85a0f372a92cb881fc80abd46789c76dfd315563 Completion/Base/Widget/_complete_debug
applying [1/1] https://inbox.vuxu.org/zsh-users/20180418135817.7edca58c@camnpupstephen.cam.scsc.local/
diff --git a/Completion/Base/Widget/_complete_debug b/Completion/Base/Widget/_complete_debug
index 85a0f37..1ff7630 100644
Checking patch Completion/Base/Widget/_complete_debug...
Applied patch Completion/Base/Widget/_complete_debug cleanly.
index at:
100644 1ff7630fb81e8fbcdbdfe24e7fe103fd695073b3 Completion/Base/Widget/_complete_debug
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).