param expansion flags

param expansion flags

[Dominic Mitchell]

I'm trying to write a completion file rake (a make like thing for ruby).
You can get a list of targets like this:

    % rake -sT
    rake apidoc                   # Build the apidoc HTML Files
    rake appdoc                   # Build the appdoc HTML Files
    rake clear_logs               # Clears all *.log files in log/

And I'm trying to get that lot into an array parameter that looks like
this:

    targets=(
        'apidoc[Build the apidoc HTML Files]'
        'appdoc[Build the appdoc HTML Files]'
        'clear_logs[Clears all *.log files in log/]'
    )

I've gotten part of the way there, but I can't figure out the rest.  So
far, I've gotten it to split out the lines, remove "rake " from the
front and start putting the initial square bracket in.

    % arr=( ${${${(f)~~"$(rake -sT)"}#rake }/ *# /[} )

Can anyone offer me some advice?

-Dom

Re: param expansion flags

[Bart Schaefer]

On May 6,  1:48pm, Dominic Mitchell wrote:
} 
} Can anyone offer me some advice?

Do it in several steps and worry later (if ever) about compressing
them down to a single nested parameter expansion.

arr=( ${(f)"$(rake -sT)"} )
arr=( ${arr#rake } )
arr=( ${arr/ *# /\[} )
arr=( ${^arr}\] )

Re: param expansion flags

[Haakon Riiser]

Dominic,

> I've gotten part of the way there, but I can't figure out the rest.  So
> far, I've gotten it to split out the lines, remove "rake " from the
> front and start putting the initial square bracket in.
> 
>     % arr=( ${${${(f)~~"$(rake -sT)"}#rake }/ *# /[} )
> 
> Can anyone offer me some advice?

This seems to work:

  arr=(${^${${${(f)~~"$(rake -sT)"}}#rake }// *# /[}}])

The only difference is that your expression is now placed into
${^...} so that the trailing ] is appended to every line.

-- 
 Haakon

Re: param expansion flags

[Dominic Mitchell]

On Fri, May 06, 2005 at 04:11:09PM +0000, Bart Schaefer wrote:
> On May 6,  1:48pm, Dominic Mitchell wrote:
> } 
> } Can anyone offer me some advice?
> 
> Do it in several steps and worry later (if ever) about compressing
> them down to a single nested parameter expansion.
> 
> arr=( ${(f)"$(rake -sT)"} )
> arr=( ${arr#rake } )
> arr=( ${arr/ *# /\[} )
> arr=( ${^arr}\] )

Thank you very much -- that's an exceedingly sensible idea.  And I
hadn't used ${^foo} before, so that's something good to learn!

Thanks again,
-Dom