From: Tobias Gruetzmacher <tobias@portfolio16.de>
To: zsh-users@sunsite.dk
Subject: Problem writing ri completion function
Date: Thu, 6 Oct 2005 18:41:12 +0200 [thread overview]
Message-ID: <20051006164111.GA8382@portfolio16.de> (raw)
[-- Attachment #1.1: Type: text/plain, Size: 1038 bytes --]
Hi,
I was writing a new completion for ri, the ruby documentation viewing
tool, when I came upon a small problem: ri takes as argument the full
name of a class, module or method.
It can generate a list of all documented functions, which I use to fill
the completion list. This list is very long, so I tried to use
_multi_parts to get a better overview. The problem is: ri uses
different separators to differentiate between class method and instance
methods. For example I have these alternatives:
File (class or module)
File::basename (class method)
File.path (instance method)
File::Stat (another class)
File::Stat::new (another class method)
I currently only use _multi_parts with "." as separator - I don't know
enough zsh scripting to build something to use multiple separators. Any
ideas?
Greetings Tobi
--
GPG-Key 0xE2BEA341 - signed/encrypted mail preferred
My, oh so small, homepage: http://portfolio16.de/
http://www.fli4l.de/ - ISDN- & DSL-Router on one disk!
Registered FLI4L-User #00000003
[-- Attachment #1.2: _ri --]
[-- Type: text/plain, Size: 1174 bytes --]
#compdef ri
#
# zsh completion for the ri ruby documentation tool
# from http://www.ruby-talk.org/cgi-bin/scat.rb/ruby/ruby-talk/128677
# + some changes
_ri () {
_arguments -C -s \
'(-h --help)'{-h,--help}'[print help message]' \
'(-c --classes)'{-c,--classes}'[Display the names of classes and modules we know about]' \
'(-d --doc-dir)'{-d+,--doc-dir+}'[A directory to search for documentation]:directory:_files -/' \
'(-f --format)'{-f,--format}'[Format to use when displaying output]:format:(ansi bs html plain simple)' \
'(-l --list-names)'{-l,--list-names}'[List all the names known to RDoc, one per line]' \
'(-T --no-pager)'{-T,--no-pager}'[Send output directly to stdout]' \
'(-w --width)'{-w+,--width+}'[output width]:width: ' \
'(-v --version)'{-v,--version}'[Display the version of ri]' \
"*:help topics:_ri_names"
}
_ri_names () {
if ( [[ ${+_ri_list_names} -eq 0 ]] || _cache_invalid ri_names ) &&
! _retrieve_cache ri_names; then
_ri_list_names=( ${$(_call_program ri--list-names RI= ri -l -T 2>/dev/null)//\#/.} )
_store_cache ri_names _ri_list_names
fi
_multi_parts -i "." _ri_list_names
}
_ri "$@"
[-- Attachment #2: Digital signature --]
[-- Type: application/pgp-signature, Size: 189 bytes --]
next reply other threads:[~2005-10-06 16:41 UTC|newest]
Thread overview: 2+ messages / expand[flat|nested] mbox.gz Atom feed top
2005-10-06 16:41 Tobias Gruetzmacher [this message]
2005-10-07 9:08 ` Alexey Tourbin
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20051006164111.GA8382@portfolio16.de \
--to=tobias@portfolio16.de \
--cc=zsh-users@sunsite.dk \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).