Any easier way of parsing this file?

Any easier way of parsing this file?

[DervishD]

    Hi all :)

    I have a file like this:

    # comment
    # more comments
    ...
    # no more coments below this line
    NOTINTERESTINGLABEL=whatever
    SOMELABEL=content1 / content 2
    ANOTHERLABEL1=content of label 1
    ANOTHERLABEL2=content of label 2
    ...
    ANOTHERLABELn=content of label n
    MORENOTINTERESTINGLABELS=blablabla
    ...
    ALOTOFNOTINTERESTINGLABELSWHICHENDSHERE=blablabla

    The file contents are contained in a parameter (long story...),
and they MUST be contained in a parameter.

    Well, I'm parsing it using this code:

# "data" contains the file data as shown above
typeset -a otherdata
print -n $data | while read line
do
    case $line in
    \#*) continue;;
    (#b)SOMELABEL=([^/]##)" / "([^$'\n']##))
        mydata1="$match[1]"
        mydata2="$match[2]"
        ;;
    (#b)ANOTHERLABEL[^=]#=(*))
        otherdata+="$match"
        ;;
    *) continue ;;
    esac
done

    Is there any better way of parsing this file using Zsh and
assuming that I may be interested in gathering the information for
other labels in the future? Yes, I know I can do this easily using
sed, but I want to do it using just Zsh code in order to avoid
dependencies. And yes, the file looks like a xmcd file from CDDB ;)

    I've tried to get the first data (the SOMELABEL data, that gives
us two items) using parameter substitution and using a conditional
expression, and both ways work, but the ANOTHERLABEL data is a
different issue and I find easier the above construct.

    Thanks a lot in advance :)

    Raúl Núñez de Arenas Coronado

-- 
Linux Registered User 88736 | http://www.dervishd.net
http://www.pleyades.net & http://www.gotesdelluna.net
It's my PC and I'll cry if I want to...

Re: Any easier way of parsing this file?

[DervishD]

    Hi all :)

    Just one additional note:

 * DervishD <zsh@dervishd.net> dixit:
> # "data" contains the file data as shown above
> typeset -a otherdata
> print -n $data | while read line
> do
>     case $line in
>     \#*) continue;;
>     (#b)SOMELABEL=([^/]##)" / "([^$'\n']##))
>         mydata1="$match[1]"
>         mydata2="$match[2]"
>         ;;
>     (#b)ANOTHERLABEL[^=]#=(*))
>         otherdata+="$match"
>         ;;
>     *) continue ;;
>     esac
> done

    I've tried to do this, too:

    set -- ${(j)data}
    for line
    ...

    I don't know if this is better :??

    Raúl Núñez de Arenas Coronado

-- 
Linux Registered User 88736 | http://www.dervishd.net
http://www.pleyades.net & http://www.gotesdelluna.net
It's my PC and I'll cry if I want to...

Re: Any easier way of parsing this file?

[Bart Schaefer]

On Oct 19, 12:53am, DervishD wrote:
}
}     The file contents are contained in a parameter (long story...),
} and they MUST be contained in a parameter.
} 
}     Is there any better way of parsing this file using Zsh and
} assuming that I may be interested in gathering the information for
} other labels in the future?

Use IFS.  That's what it's for.

	print -r $data | while IFS='=' read label content
	do
	    case $label in
	    SOMELABEL) : ... $content ... ;;
	    ANOTHERLABEL) : ... $content ... ;;
	    esac
	done

Re: Any easier way of parsing this file?

[DervishD]

    Hi Bart :)

 * Bart Schaefer <schaefer@brasslantern.com> dixit:
> On Oct 19, 12:53am, DervishD wrote:
> }
> }     The file contents are contained in a parameter (long story...),
> } and they MUST be contained in a parameter.
> } 
> }     Is there any better way of parsing this file using Zsh and
> } assuming that I may be interested in gathering the information for
> } other labels in the future?
> 
> Use IFS.  That's what it's for.
> 
> 	print -r $data | while IFS='=' read label content
> 	do
> 	    case $label in
> 	    SOMELABEL) : ... $content ... ;;
> 	    ANOTHERLABEL) : ... $content ... ;;
> 	    esac
> 	done

    Well, I was more interested in an alternative for the "print |
while read" but this is a good idea too. Less complex patterns.

    Thanks a lot, Bart :)

    Raúl Núñez de Arenas Coronado

-- 
Linux Registered User 88736 | http://www.dervishd.net
http://www.pleyades.net & http://www.gotesdelluna.net
It's my PC and I'll cry if I want to...

Re: Any easier way of parsing this file?

[Bart Schaefer]

On Oct 19,  9:37am, DervishD wrote:
} 
}   I was more interested in an alternative for the "print | while read"

Such as
	for line in "${(f)data}"
perhaps?

Actually in 4.2.5 you can probably do

	for label content in "${(j/=/s/=/)${(f)data}}"

as long as none of the content parts contain equal signs.

Re: Any easier way of parsing this file?

[DervishD]

    Hi Bart :)

 * Bart Schaefer <schaefer@brasslantern.com> dixit:
> On Oct 19,  9:37am, DervishD wrote:
> } 
> }   I was more interested in an alternative for the "print | while read"
> 
> Such as
> 	for line in "${(f)data}"
> perhaps?

    Yes!. I tried that the first time and it didn't work, probably
because of the \C-M mess. Anyway I dropped that while I still hadn't
the \C-M thing fixed. Now that it is fixed I can try that. In fact
the code is still there, but commented ;)

    Thanks for pointing :)
 
> Actually in 4.2.5 you can probably do
> 
> 	for label content in "${(j/=/s/=/)${(f)data}}"
> 
> as long as none of the content parts contain equal signs.

    They can, unfortunately :(

    Thanks for the help, Bart :) 

    Raúl Núñez de Arenas Coronado

-- 
Linux Registered User 88736 | http://www.dervishd.net
http://www.pleyades.net & http://www.gotesdelluna.net
It's my PC and I'll cry if I want to...