From: ZyX <zyx@np.by>
To: John Eikenberry <jae@zhar.net>, zsh-users@zsh.org
Subject: Re: Suffix alias for README files
Date: Wed, 20 Apr 2011 22:40:22 +0400 [thread overview]
Message-ID: <201104202240.22873@-zyx> (raw)
In-Reply-To: <20110420172543.GK6935@mollari.zhar.net>
[-- Attachment #1: Type: Text/Plain, Size: 2627 bytes --]
Reply to message «Re: Suffix alias for README files»,
sent 21:25:43 20 April 2011, Wednesday
by John Eikenberry:
> Is there any way to get either of these to work without changing the
> command that is stored in history? So the history contains
> '/some/path/README' and not 'less /some/path/README'?
Yes, of course. I personally use the following code:
function zshaddhistory()
{
emulate -L zsh
if ! [[ -z "${_HISTLINE}" ]] ; then
print -sr -- "${_HISTLINE}"
unset _HISTLINE
else
print -sr -- "${1%%$'\n'}"
fi
fc -p
}
With this function if you set variable _HISTLINE somewhere before zshaddhistory
hook is run then contents of _HISTLINE will be put into the history. Widget
accept-line is called before zshaddhistory.
Here is where I actually use _HISTLINE (with just the same purpose: execute one
command, but add to history another):
function _-accept-line()
{
emulate -L zsh
local -r autopushd=${options[autopushd]}
options[autopushd]=off
cd $PWD || cd
options[autopushd]=$autopushd
if [[ ${BUFFER[1,3]} == ":h " ]] ; then
_HISTLINE=$BUFFER
BUFFER=":h ${(q)BUFFER[4,-1]}"
elif [[ ${BUFFER[1,4]} == "zmw " ]] ; then
_HISTLINE=$BUFFER
BUFFER="zmw "${(j. .)${(q)${(z)BUFFER[5,-1]}}}
fi
zle .accept-line
}
Original message:
> Bart Schaefer wrote:
> > > I can use suffix aliases to display various .txt files.
> > > Can I do a similar thing for README files? So the "command"
> > >
> > > /some/path/README
> > >
> > > will really run the command
> > >
> > > less /some/path/README
> >
> > Depending on your version of zsh, you can do this either with the
> > zle-line-finish widget or by replacing the accept-line widget.
> >
> > zle-line-finish() {
> >
> > setopt localoptions extendedglob
> > if [[ -z "$PREBUFFER" && "$BUFFER" = ([^[:space:]]#/)#README ]]
> > then BUFFER="less $BUFFER"
> > fi
> >
> > }
> > zle -N zle-line-finish
> >
> > Or
> >
> > accept-line() {
> >
> > setopt localoptions extendedglob
> > if [[ -z "$PREBUFFER" && "$BUFFER" = ([^[:space:]]#/)#README ]]
> > then BUFFER="less $BUFFER"
> > fi
> > zle .accept-line "$@"
> >
> > }
> > zle -N accept-line
>
> Is there any way to get either of these to work without changing the
> command that is stored in history? So the history contains
> '/some/path/README' and not 'less /some/path/README'?
[-- Attachment #2: This is a digitally signed message part. --]
[-- Type: application/pgp-signature, Size: 198 bytes --]
next prev parent reply other threads:[~2011-04-20 19:14 UTC|newest]
Thread overview: 9+ messages / expand[flat|nested] mbox.gz Atom feed top
2011-04-19 13:59 Anthony R Fletcher
2011-04-20 9:23 ` Sebastian Stark
2011-04-20 12:41 ` Anthony R Fletcher
2011-04-20 15:06 ` Bart Schaefer
2011-04-20 16:44 ` Anthony R Fletcher
2011-04-20 17:25 ` John Eikenberry
2011-04-20 18:40 ` ZyX [this message]
2011-04-20 18:57 ` John Eikenberry
2011-04-20 19:22 ` ZyX
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=201104202240.22873@-zyx \
--to=zyx@np.by \
--cc=jae@zhar.net \
--cc=zsh-users@zsh.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).