Re: completion function for system_profiler (OS X)

[luc <luc.lists@gmail.com>]

[-- Attachment #1: Type: text/plain, Size: 725 bytes --]

Hello Jun,

> You can simply use '*:message:action' as a spec for _arguments.
This works perfectly.
> Output from $(system_profiler -listDataTypes) contains a header line,
> which is removed by ( ${$(f)"$(command)"}[2,-1]} ).
> You are using _call_program so a user can replace the command by using
> zstyle. But the 1st line of the output from the user-specified command
> will also be removed.
I am now hardcoding the data types into the array as the call for
`system_profiler -listDataTypes` is taking a lot of time sometimes.  I
think this list hardly ever changes (in new versions of OS X?).

I will attach my "final" version again.  Is it reasonalble (or desired)
to commit this upsream?

Thank you for your help
Lucas

[-- Attachment #2: _system_profiler --]
[-- Type: text/plain, Size: 1311 bytes --]

#compdef system_profiler

typeset -A opt_args
local context state state_descr line
local -a _data_types

# TODO: Should this be static?  Calling `system_profiler -listDataTypes` takes
# about 0.07-0.08 secs on my machine.  Does this list ever change (between
# different versions of OS X)?
_data_types=( SP{AirPort,Applications,Audio,Bluetooth,Camera,CardReader,Component,ConfigurationProfile,DeveloperTools,Diagnostics,DisabledSoftware,DiscBurning,Displays,Ethernet,Extensions,FibreChannel,FireWire,Firewall,Fonts,Frameworks,Hardware,HardwareRAID,InstallHistory,Logs,ManagedClient,Memory,Network,NetworkLocation,NetworkVolume,PCI,ParallelATA,ParallelSCSI,Power,PrefPane,Printers,PrintersSoftware,SAS,SPI,SerialATA,Software,StartupItem,Storage,SyncServices,Thunderbolt,USB,UniversalAccess,WWAN}DataType )
# the dynamic alternative is:
#_data_types=( ${${(f)"$(_call_program path system_profiler -listDataTypes 2>/dev/null)"}[2,-1]} )

_arguments \
  '(- *)-usage' \
  '(- *)-listDataTypes[lists the available datatypes]' \
  '(-listDataTypes -usage)-xml[generate xml output]' \
  '(-listDataTypes -usage)-detailLevel[level of detail for the report]:detail level:(mini basic full)' \
  '(-listDataTypes -usage)-timeout+[maximum time to wait in seconds]' \
  '(-listDataTypes -usage)*:data type:'"($_data_types)"