Re: completing a single clearcase command

[Peter Stephenson <pws@csr.com>]

Eric.D.Friedman@WellsFargo.COM wrote:
> The subcommand I'm interested in getting completion on is "setview," which
> has the following usage:
> 
> Usage: setview [-login] [-exec command-invocation] view-tag
> 
> The view-tag argument will be a name pulled from the list of available
> views.  A list of these can be gotten (1 entry per line) by running
> "cleartool lsview -short"

Exactly this sort of thing is done by the _p4 script I submitted to the
archive (it's in 4.1.0-dev-7).  I suspect bits of Perforce were inspired
by ClearCase.  In particular, _p4_clients extracts a list of `clients',
which are sort of a bit like a view (only not so flexible).

> But, I'd like to still be able to get file completion and so forth on other
> clearcase subcommands, so it's important that that not be disabled in the
> process.

The following should do exactly what you want --- and no more, but it
should be obvious where to put extra handling.  It's not in the most
extensible form, but it is in about the most transparent.

As look would have it, we have ClearCase here for a month's evaluation,
so I was able to test this.  It's obviously not the best start for a
completely general completion.

(Purists might object to my use of `_describe', but it's a nice easy way
of injecting a description and a tag if you can't remember the syntax
for compadd :-/)


#compdef cleartool

local -a array
if (( CURRENT == 2 )); then
  # We are completing the subcommand word; no point
  # in doing files here.  A simple way of adding a list is
  array=($(cleartool help | awk '$1 == "Usage:" { print $2 }'))
  _describe -t subcommands 'cleartool command' array
else
  # We are after the subcommand, so we can examine it.
  # Decide if it's something we want to handle here, or
  # just let default completion take over.
  case $words[2] in
      (setview) array=($(cleartool lsview -short))
		_describe -t views 'ClearCase view' array
		;;
      (*) _default
          return
	  ;;
  esac
fi

-- 
Peter Stephenson <pws@csr.com>                  Software Engineer
CSR Ltd., Science Park, Milton Road,
Cambridge, CB4 0WH, UK                          Tel: +44 (0)1223 692070


**********************************************************************
The information transmitted is intended only for the person or
entity to which it is addressed and may contain confidential 
and/or privileged material. 
Any review, retransmission, dissemination or other use of, or
taking of any action in reliance upon, this information by 
persons or entities other than the intended recipient is 
prohibited.  
If you received this in error, please contact the sender and 
delete the material from any computer.
**********************************************************************