Re: multiple background jobs of the same program

["Bart Schaefer" <schaefer@brasslantern.com>]

On Sep 14, 10:28am, Adam R. Paul wrote:
} Subject: Re: multiple background jobs of the same program
}
} setopt interactive_comments
} 
} listjobs() {
} jobs > /tmp/._zshjobcomp.$$ 2>&1
} set -A reply
} OIFS="$IFS"
} IFS='
} '
} reply=( $(sed -e '{
} s/.\(....\).............\(.*\)/\1 # \2/g
} s/\]//g
} s/  */ /g
} }' /tmp/._zshjobcomp.$$) )
} IFS="$OIFS"
} }
} 
} compctl -P % -K listjobs fg
} 
} The only problem is that zsh is escaping the spaces & #'s that result

Change it to

	compctl -Q -P % -K listjobs fg

} Also, I don't really want 
} interactive_comments set all the time

Replace the `#' with `;:'.  This works best if you have menu completion
so that the `;' isn't interpreted as a command separator until after you
have a chance to cycle through all the possibilities.

} Any improvements?

Either remove the temp file or use >| so `setopt clobber' isn't needed.

You don't need `set -A reply'.

Don't change IFS, use "${(@f)...}" to interpret each line as a word.

Have listjobs insert the leading % instead of using -P, and use -U to
cause the line so far to be replaced by the completion.   Then when there
are no possible completions (no jobs), nothing gets inserted.  (Your
original inserts "% " when there are no jobs.)

Do the completion for `bg' and `kill', too.

} I suspect that the sed bit could be replaced by some neato
} zsh internal parameter mangling stuff

Since you're doing several substitutions and already reading from a file,
I don't think that's worth it.

Finished product:

listjobs() {
  jobs >| /tmp/._zshjobcomp.$$ 2>&1
  reply=( "${(@f)$(sed -e '{
    s/.\(....\).............\(.*\)/%\1 ;: \2/g
    s/\]//g
    s/  */ /g
    }' /tmp/._zshjobcomp.$$)}" )
}

compctl -U -Q -K listjobs fg bg kill

-- 
Bart Schaefer                                 Brass Lantern Enterprises
http://www.well.com/user/barts              http://www.brasslantern.com