case insensitive string match

case insensitive string match

[rahul]

[-- Attachment #1: Type: text/plain, Size: 421 bytes --]

I've been using this for doing some filtering from an array:

                matched=(${(M)array:#*$patt*})

Now I need to have an option of case insensitive search. Looked through the
user's guide and other sources but I don't see a flag to ignore case. Is
there a way without changing this to use grep.

I also dont suppose approximate matching can be used here (that's only for
filename globbing, right?)

-- 
 rahul

Re: case insensitive string match

[Peter Stephenson]

On Thu, 03 Jan 2013 16:03:56 +0530
rahul <rahul2012@gmail.com> wrote:
> I've been using this for doing some filtering from an array:
> 
>                 matched=(${(M)array:#*$patt*})
> 
> Now I need to have an option of case insensitive search. Looked
> through the user's guide and other sources but I don't see a flag to
> ignore case. Is there a way without changing this to use grep.
 

Make sure the extendedglob option is on:

                 setopt extendedglob

and use

                 matched=(${(M)array:#(#i)*$patt*})

> I also dont suppose approximate matching can be used here (that's
> only for filename globbing, right?)

That should work fine; apart from glob qualifiers, which can't be used
with patterns whatever effect they have, about the only things limited
to filename globbing are things that really only apply to files.

pws

Re: case insensitive string match

[Frank Terbeck]

(Forgot the mailinglist in my first reply, readding)

rahul wrote:
> On Thu, Jan 3, 2013 at 4:31 PM, Frank Terbeck <ft@bewatermyfriend.org>wrote:
>
>> rahul wrote:
>> > been using this for doing some filtering from an array:
>> >
>> >                 matched=(${(M)array:#*$patt*})
>> >
>> > Now I need to have an option of case insensitive search. Looked through
>> the
>> > user's guide and other sources but I don't see a flag to ignore case. Is
>> > there a way without changing this to use grep.
>>
>> % things=( foo bar bfoor thing other frob )
>> % print -l ${(M)things:#*(#i)foo*}
>> foo
>> bfoor
>>
>> Thanks a lot. I think you meant:
>
>     % print -l ${(M)things:#(#i)*foo*}

Actually, I didn't. The position of the (#i) determines where the
case-insensitivity starts. `*' matches everything anyway, so making it
case-insensitive does not add much.

> When i typed in what you wrote I got a "zsh bad pattern"

Works here, maybe you're missing "setopt extended_glob"?


Regards, Frank

Re: case insensitive string match

[Frank Terbeck]

rahul wrote:
>> >> Thanks a lot. I think you meant:
>> >
>> >     % print -l ${(M)things:#(#i)*foo*}
>>
>> Actually, I didn't. The position of the (#i) determines where the
>> case-insensitivity starts. `*' matches everything anyway, so making it
>> case-insensitive does not add much.
>>
>> > When i typed in what you wrote I got a "zsh bad pattern"
>>
>> Works here, maybe you're missing "setopt extended_glob"?
>>
>>
>> I still get a bad pattern. I am on the latest zsh (homebrew on OSX). I
> added an entry called FOO and it comes up in the match.
>
> setopt extended_glob
>
> print -l ${(M)things:#*(#i)foo*}
> zsh: bad pattern: *(#i)foo*
>
> print -l ${(M)things:#(#i)*foo*}
> foo
> bfoor
> FOO
>
> echo $ZSH_VERSION
> 5.0.2

Weird, here both work. From zsh -f (which starts a shell without setup
files):

[snip]
zsh% setopt extended_glob
zsh% things=( foo bar bfoor thing FOO other frob )
zsh% print -l ${(M)things:#(#i)*foo*}
foo
bfoor
FOO
zsh% print -l ${(M)things:#*(#i)foo*}
foo
bfoor
FOO
[snap]

Are you maybe setting the `kshglob' option? Does it work if you do:

% setopt no_ksh_glob

Regards, Frank

-- 
In protocol design, perfection has been reached not when there is
nothing left to add, but when there is nothing left to take away.
                                                  -- RFC 1925