From: Roman Perepelitsa <roman.perepelitsa@gmail.com>
To: linuxtechguy@gmail.com
Cc: zsh <zsh-users@zsh.org>
Subject: Re: special characters in file names issue
Date: Fri, 10 Nov 2023 10:50:58 +0100 [thread overview]
Message-ID: <CAN=4vMq6bKP5fh3yu-o1ROmoV=QFsFMnwNPP9wbgX4NgZbfdAQ@mail.gmail.com> (raw)
In-Reply-To: <CA+rB6GLYBa3RMo+dDwk4FtdQ=HB_ix+g3UWqiVJ7ko6DAAVLdA@mail.gmail.com>
On Fri, Nov 10, 2023 at 12:17 AM Jim <linux.tech.guy@gmail.com> wrote:
>
> Hi everyone,
>
> Using scripts, looking to cleanup duplicate files even if named differently.
> The issue I ran into is when a file path contains parentheses. '(' or ')'
>
> Example File Name: Wallpapers/Web_downloads/05 (1).jpg
>
> The following is part of an anonymous function:
>
> local E
> local -a AllFileNames
> local -A FileNameCkSum
> ...
> for E (${(@)AllFileNames}) {
> [[ -v FileNameCkSum[$E] ]] || FileNameCkSum[$E]=${$(shasum -a 1 $E)[1]} } # line that fails
> ...
>
> AllFileName contains the result of a glob statement.
>
> Error Message: (anon):<line no>: invalid subscript
Associative arrays in zsh are finicky when it comes to the content of
their keys. The problem you are experiencing can be distilled to this:
% typeset -A dict
% key='('
% [[ -v dict[$key] ]]
zsh: invalid subscript
There is no simple quoting that you can apply to $key here: (q), (b),
etc. are all wrong. You could perhaps escape a specific list of
characters ('(', '[', '{' but not '$' or '*') although my memory tells
me that some keys cannot be made to work under `[[ -v ...]]` or
`unset` no matter how you try to escape them. I could be wrong though.
I usually apply one of two workarounds: use hash($x) instead of $x as
a key, or replace the associative array with two plain arrays, one for
keys and another for values. The latter results in O(N) lookup though.
Roman.
P.S.
From the description of your problem I would think that you want file
hashes as keys. Something like this:
# usage: detect-dup-files [file]..
function detect-dup-files() {
emulate -L zsh
(( ARGC )) || return 0
local -A seen
local i files fname hash orig
files=( $(shasum -ba 256 -- "$@") ) || return
(( 2 * ARGC == $#files )) || return
for i in {1..$ARGC}; do
fname=$argv[i]
hash=${files[2*i-1]#\\}
if [[ -n ${orig::=$seen[$hash]} ]]; then
print -r -- "${(q+)fname} is a dup of ${(q+)orig}"
else
seen[$hash]=$fname
fi
done
}
This code has an added advantage of forking only once. It also handles
file names with backslashes and linefeeds in them.
next prev parent reply other threads:[~2023-11-10 9:52 UTC|newest]
Thread overview: 15+ messages / expand[flat|nested] mbox.gz Atom feed top
2023-11-09 23:16 Jim
2023-11-10 5:04 ` Mikael Magnusson
2023-11-10 9:50 ` Roman Perepelitsa [this message]
2023-11-10 14:17 ` Mikael Magnusson
2023-11-10 14:28 ` Roman Perepelitsa
2023-11-11 18:26 ` Jim
2023-11-10 16:33 ` Lawrence Velázquez
2023-11-10 17:02 ` Bart Schaefer
2023-11-10 20:37 ` Roman Perepelitsa
2023-11-11 0:13 ` Bart Schaefer
2023-11-11 17:18 ` Ray Andrews
2023-11-11 18:19 ` Bart Schaefer
2023-11-11 18:52 ` Ray Andrews
2023-11-11 18:26 ` Jim
2023-11-12 0:08 ` Bart Schaefer
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to='CAN=4vMq6bKP5fh3yu-o1ROmoV=QFsFMnwNPP9wbgX4NgZbfdAQ@mail.gmail.com' \
--to=roman.perepelitsa@gmail.com \
--cc=linuxtechguy@gmail.com \
--cc=zsh-users@zsh.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).