Re: completion function for system_profiler (OS X)

["Jun T." <takimoto-j@kba.biglobe.ne.jp>]

2014/02/05 21:00, luc <luc.lists@gmail.com> wrote:

> My problem is the third posibility:  I do not know how to tell the completion
> system to allow several dataTypes after the command.  I store the dataTypes in
> an array which I populate with `system_profiler -listDataTypes`.  How can I
> tell zsh that any of these strings may follow in any order several times,
> unless -usage or -listDataTypes is given?  My code so far is attached.

You can simply use '*:message:action' as a spec for _arguments. This can
complete any number of normal arguments. As the 'action', you can use
'(val1 val2 ...)' as you have already used for the option -detailLevel.
So the simplest possibility may be the following:

-----------
#compdef system_profiler

local context state state_descr line 
typeset -A opt_args
local -a _data_types

_data_types=( ${${(f)"$(_call_program datatypes system_profiler -listDataTypes 2>/dev/null)"}[2,-1]} )

_arguments \
  '(- *)-usage' \
  '(- *)-listDataTypes[lists the available datatypes]' \
  '(-listDataTypes -usage)-xml[generate xml output]' \ 
  '(-listDataTypes -usage)-detailLevel[level of detail for the report]:detail level:(mini basic full)' \
  '(-listDataTypes -usage)-timeout+[maximum time to wait in seconds]' \
  '*:data type:'"($_data_types)"
-----------

Output from $(system_profiler -listDataTypes) contains a header line,
which is removed by ( ${$(f)"$(command)"}[2,-1]} ).
You are using _call_program so a user can replace the command by using
zstyle. But the 1st line of the output from the user-specified command
will also be removed.