zsh-workers
 help / color / mirror / Atom feed
05d26f2e76526c3f9d8d5267d465c5fef7a3e2f3 blob 2417 bytes (raw)

 1
 2
 3
 4
 5
 6
 7
 8
 9
10
11
12
13
14
15
16
17
18
19
20
21
22
23
24
25
26
27
28
29
30
31
32
33
34
35
36
37
38
39
40
41
42
43
44
45
46
47
48
49
50
51
52
53
54
55
56
57
58
59
60
 
#compdef -P python[0-9.]#

# Python 2.7
# Python 3.9

local curcontext="$curcontext" state state_descr line
typeset -A opt_args
local -a args

if _pick_variant python3=Python\ 3 python2 --version; then
  args=(
    '(-bb)-b[issue warnings about str(bytes_instance), str(bytearray_instance) and comparing bytes/bytearray with str]'
    '(-b)-bb[issue errors about str(bytes_instance), str(bytearray_instance) and comparing bytes/bytearray with str]'
    '--check-hash-based-pycs[configure how Python evaluates up-to-dateness of hash-based .pyc files]:mode'
    "-I[isolate Python from the user's environment]"
    '-q[do not print version and copyright messages]'
    '-X[set implementation-specific option]:option'
  )
else
  args=(
    '-R[use a pseudo-random salt to make hash values unpredictable]'
    '-Q+[division options]:division option:(old warn warnall new)'
    '(-tt)-t[issue warnings about inconsistent tab usage]'
    '(-t)-tt[issue errors about inconsistent tab usage]'
    '-3[warn about Python 3.x incompatibilities]'
  )
fi

_arguments -C -s -S "$args[@]" \
  "-B[don't write .py\[co\] files on import]" \
  '(1 -)-c+[program passed in as string (terminates option list)]:python command' \
  '-d[debug output from parser]' \
  '-E[ignore PYTHON* environment variables (such as PYTHONPATH)]' \
  '(1 * -)-h[display help information]' \
  '-i[inspect interactively after running script]' \
  '(1 -)-m+[run library module as a script (terminates option list)]:module:_python_modules' \
  '-O[optimize generated bytecode slightly]' \
  '-OO[remove doc-strings in addition to the -O optimizations]' \
  "-s[don't add user site directory to sys.path]" \
  "-S[don't imply 'import site' on initialization]" \
  '-u[unbuffered binary stdout and stderr]' \
  '(-vv)-v[trace module initialization and cleanup]' \
  '(-v)-vv[in addition to -v, trace all files checked when searching for a module]' \
  '(1 * -)-V[display version information]' \
  '-W+[warning control]:warning filter (action\:message\:category\:module\:lineno):(default always ignore module once error)' \
  '-x[skip first line of source, allowing use of non-Unix forms of #!cmd]' \
  '(-)1:Python script:_files -g "*.py(|c|o)(-.)"' \
  '*::script argument:= ->normal' && return

case "$state" in
  normal)
    if [[ -z "$opt_args[(I)-(c|m)]" ]]; then
      shift words
      (( CURRENT-- ))
    fi
    _normal && return
    ;;
esac

return 1
debug log:

solving 05d26f2e7652 ...
found 05d26f2e7652 in https://inbox.vuxu.org/zsh-workers/20210726221050.764873-1-stepnem@gmail.com/
found f10106f9b4d9 in https://git.vuxu.org/mirror/zsh/
preparing index
index prepared:
100644 f10106f9b4d9c1b82de73affa375fa97b8092eb5	Completion/Unix/Command/_python

applying [1/1] https://inbox.vuxu.org/zsh-workers/20210726221050.764873-1-stepnem@gmail.com/
diff --git a/Completion/Unix/Command/_python b/Completion/Unix/Command/_python
index f10106f9b4d9..05d26f2e7652 100644

Checking patch Completion/Unix/Command/_python...
Applied patch Completion/Unix/Command/_python cleanly.

index at:
100644 05d26f2e76526c3f9d8d5267d465c5fef7a3e2f3	Completion/Unix/Command/_python

zsh-workers

This inbox may be cloned and mirrored by anyone:

	git clone --mirror https://inbox.vuxu.org/zsh-workers

	# If you have public-inbox 1.1+ installed, you may
	# initialize and index your mirror using the following commands:
	public-inbox-init -V1 zsh-workers zsh-workers/ https://inbox.vuxu.org/zsh-workers \
		zsh-workers@zsh.org
	public-inbox-index zsh-workers

Example config snippet for mirrors.
Newsgroup available over NNTP:
	nntp://inbox.vuxu.org/vuxu.archive.zsh.workers


code repositories for the project(s) associated with this inbox:

	https://git.vuxu.org/mirror/zsh/

AGPL code for this site: git clone https://public-inbox.org/public-inbox.git