From: Daniel Shahaf <d.s@daniel.shahaf.name>
To: zsh-workers@zsh.org
Subject: [PATCH] _apt: Complete package versions in the 'packagename=<version>' syntax.
Date: Sat, 17 Sep 2016 09:44:00 +0000 [thread overview]
Message-ID: <1474105440-2232-1-git-send-email-danielsh@fujitsu.shahaf.local2> (raw)
---
Completion/Debian/Command/_apt | 41 ++++++++++++++++++++++++++++++++++++++++-
1 file changed, 40 insertions(+), 1 deletion(-)
diff --git a/Completion/Debian/Command/_apt b/Completion/Debian/Command/_apt
index a46c326..d92d2f8 100644
--- a/Completion/Debian/Command/_apt
+++ b/Completion/Debian/Command/_apt
@@ -464,7 +464,11 @@ _apt-get () {
\( \
/$'install\0'\|$'download\0'\|$'source\0'\|$'build-dep\0'/ \
/$'[^\0]#\0'/ ':packages::_deb_packages "$expl_packages[@]" avail' \# \
- /$'[^\0/]#/'/ /$'[^\0/]#\0'/ ':release name::_apt_releases' \) \| \
+ \( \
+ /$'[^\0/]#/'/ /$'[^\0/]#\0'/ ':release name::_apt_releases' \| \
+ /$'[^\0=]#='/ /$'[^\0=]#\0'/ ':package version::_apt_versions_of_binary_package' \
+ \) \
+ \) \| \
/$'remove\0'/ /$'[^\0]#\0'/ ':packages::_deb_packages "$expl_packages[@]" installed' \# \| \
/$'purge\0'/ /$'[^\0]#\0'/ ':packages::_deb_packages "$expl_packages[@]" installed' \# \| \
/$'dist-upgrade\0'/ \| \
@@ -614,6 +618,41 @@ _apt_releases () {
_tags apt-releases && compadd -a _apt_releases
}
+# Complete versions of the package named in $match[1].
+#
+# Interpret the package name as a binary package (even if there is
+# a source package by that name, too).
+_apt_versions_of_binary_package() {
+ local package_name=${match[1]%=} # $match was set by _regex_arguments
+ local line
+ local name version source
+ local -a kv
+
+ for line in ${(f)"$(_call_program versions-of-package "apt-cache madison $package_name")"}; do
+ # If $package_name is a source package name, we'll have lines of the form
+ # $package_name | $version | ...Sources
+ #
+ # If $package_name is a binary package name, we'll have lines of the form
+ # $package_name | $version | ...Packages
+ # $src_package_name | $version | ...Sources
+ for name version source in "${(@s. | .)line}"; do
+ # Remove leading/trailing whitespace
+ name=${name// }
+ version=${version// }
+ source=${${source# ##}% ##}
+
+ # Skip source packages
+ if [[ $name != $package_name ]] || [[ $source != *Packages* ]]; then
+ continue
+ fi
+
+ kv+=( "${version//:/\\:}:$source" )
+ done
+ done
+
+ _describe -t apt-package-versions "package versions" kv "$@"
+}
+
_apt_caching_policy () {
local -a oldp
reply other threads:[~2016-09-17 9:45 UTC|newest]
Thread overview: [no followups] expand[flat|nested] mbox.gz Atom feed
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=1474105440-2232-1-git-send-email-danielsh@fujitsu.shahaf.local2 \
--to=d.s@daniel.shahaf.name \
--cc=zsh-workers@zsh.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).