Re: ZSH SSH completion with new Include directive in OpenSSH

[Bart Schaefer <schaefer@brasslantern.com>]

On May 25,  9:51am, Nikola Milojevic wrote:
}
} I've stumbled upon that ssh completion doesn't work with the new Include
} directive in OpenSSH 7.3. That commands include ssh config files from the
} custom folder you set.
} 
} Do you have it in a roadmap to fix that?

I've forgotten again now why we have this:

  # If users-hosts matches, we shouldn't complete anything else.

My ~/.ssh/config is never read, period, because users-hosts always
returns something.

Nevertheless I suppose you're looking for something like the following
(the "Match" directive is unlikely ever to be interpreted):

diff --git a/Completion/Unix/Command/_ssh b/Completion/Unix/Command/_ssh
index 6763e24..cd106ad 100644
--- a/Completion/Unix/Command/_ssh
+++ b/Completion/Unix/Command/_ssh
@@ -680,17 +680,23 @@ _ssh_hosts () {
     config="$HOME/.ssh/config"
   fi
   if [[ -r $config ]]; then
-    local key hosts host
-    while IFS=$'=\t ' read -r key hosts; do
-      if [[ "$key" == (#i)host ]]; then
-         for host in ${(z)hosts}; do
-            case $host in
-            (*[*?]*) ;;
-            (*) config_hosts+=("$host") ;;
-            esac
-         done
-      fi
-    done < "$config"
+    local key line host
+    local -a lines=("${(@f)$(<"$config")}")
+    while (($#lines)); do
+      IFS=$'=\t ' read -r key line <<<"${lines[1]}"
+      case "$key" in
+      ((#i)include)
+        lines[1]=("${(@f)$(cd $HOME/.ssh; cat ${(z)~line})}");;
+      ((#i)host(|name))
+        for host in ${(z)line}; do
+          case $host in
+          (*[*?]*) ;;
+          (*) config_hosts+=("$host") ;;
+          esac
+        done; ;&
+      (*) shift lines;;
+      esac
+    done
     if (( ${#config_hosts} )); then
       _wanted hosts expl 'remote host name' \
         compadd -M 'm:{a-zA-Z}={A-Za-z} r:|.=* r:|=*' "$@" $config_hosts