From: Oliver Kiddle <okiddle@yahoo.co.uk>
To: zsh-workers@zsh.org
Subject: Re: [PATCH] completion: Add FreeBSD's watch(1)
Date: Tue, 02 Jun 2015 00:19:39 +0200 [thread overview]
Message-ID: <18592.1433197179@thecus.kiddle.eu> (raw)
In-Reply-To: <20150523101555.GF1889@tarsus.local2>
On 23 May, Daniel Shahaf wrote:
> We may need a _ttys function.
That seems like a good idea. The pattern for ttys has been duplicated a
few times and this will make it easier if the system variations in the
device names is more peculiar than we have so far assumed.
This _ttys function allows the /dev/ prefix to be optional, required or
stripped. I think there's a bug somewhere in the hidden prefix handling
that this shows up, however.
Oliver
diff --git a/Completion/Unix/Command/_gdb b/Completion/Unix/Command/_gdb
index 48c9d65..f387c87 100644
--- a/Completion/Unix/Command/_gdb
+++ b/Completion/Unix/Command/_gdb
@@ -5,17 +5,19 @@ local cur="$words[CURRENT]" prev w list ret=1 expl
[[ "$PREFIX" = --* ]] &&
_arguments -- '*=(CORE|SYM)FILE:core file:_files' \
'*=EXECFILE:executable:_files -g \*\(-\*\)' \
- '*=TTY:terminal device:compadd /dev/tty\*' && return 0
+ '*=TTY:terminal device:_ttys' && return 0
if compset -P '-(cd|directory)='; then
_files -/
elif compset -P '-tty='; then
- _wanted devices expl 'terminal device' compadd - /dev/tty*
+ _wanted devices expl 'terminal device' _ttys
elif compset -P '-(exec|se)='; then
_description files expl executable
_files "$expl[@]" -g '*(-*)'
elif compset -P '-(symbols|core|command)='; then
_files
+elif compset -P '--pid='; then
+ _pids
elif [[ "$PREFIX" = -* ]]; then
_tags options
while _tags; do
diff --git a/Completion/Unix/Command/_last b/Completion/Unix/Command/_last
index 706d82f..f198e0f 100644
--- a/Completion/Unix/Command/_last
+++ b/Completion/Unix/Command/_last
@@ -9,7 +9,7 @@ for pattern arg in \
'((free|net|open)bsd*|darwin*|dragonfly*|linux-gnu)' '-h[limit sessions by hostname]:host:_hosts' \
'((free|open)bsd*|linux-gnu)' '-s[report duration in seconds]' \
'(freebsd*|openbsd*)' '-d[limit sessions to those active at snapshot time]:time ([[CC]YY][MMDD]hhmm[.SS])' \
- '((net|free|open)bsd*|darwin*|dragonfly*)' '-t[limit sessions by tty]:tty:compadd -a ttys' \
+ '((net|free|open)bsd*|darwin*|dragonfly*)' '-t[limit sessions by tty]:tty:_ttys -D' \
'openbsd*' '-c[calculate total time]' \
'^darwin*' '-f[specify account file]:file:_files' \
'(solaris*|linux-gnu|freebsd*|openbsd*)' '-n[specify number of lines to show]:number' \
@@ -45,7 +45,7 @@ case $OSTYPE in
esac
if [[ $OSTYPE = (linux-gnu|solaris*) ]]; then
- args+=( '*:arg: _alternative "users:user:_users" "ttys:tty:compadd -a ttys"' )
+ args+=( '*:arg: _alternative "users:user:_users" "ttys:tty:_ttys -d" "ttys:tty:(reboot)"' )
else
args+=( '*:user:_users' )
fi
diff --git a/Completion/Unix/Command/_pgrep b/Completion/Unix/Command/_pgrep
index d3dcd18..0b7d23d 100644
--- a/Completion/Unix/Command/_pgrep
+++ b/Completion/Unix/Command/_pgrep
@@ -13,7 +13,7 @@ arguments=('-P[parent process id]:parent process id:->ppid'
'-M[extract the name list from the specified core]:files:_files'
'-N[extract the name list from the specified system]:files:_files'
'-s[match only session id]:session id:->sid'
- '-t[match only controlled by terminal]:terminal device:->tty'
+ '-t[match only controlled by terminal]:terminal device:_sequence _ttys -d'
'-T[match only in processes specified routing table in rtable]'
'-u[match only effective user id]:user:_users'
'-U[match only real user id]:user:_users'
@@ -69,12 +69,6 @@ arguments=( ${(M)arguments:#(|\*)(|\(*\))-[$optchars]*}
_arguments -C -s -w $arguments && ret=0
case $state in
- (tty)
- local -a ttys
- ttys=( /dev/tty*(N) /dev/pts/*(N) )
- _sequence -s , _wanted tty expl 'terminal device' compadd - ${ttys#/dev/}
- ;;
-
(sid)
if [[ $OSTYPE == openbsd* ]]; then
break
diff --git a/Completion/Unix/Command/_ps b/Completion/Unix/Command/_ps
index e557b27..6f67f79 100644
--- a/Completion/Unix/Command/_ps
+++ b/Completion/Unix/Command/_ps
@@ -31,7 +31,7 @@ args=(
'*-G+[select processes by real group]:group:_sequence -s , _groups'
'*-g+[select processes by effective group or session]:group:_sequence -s , _groups'
'*-s+[select processes by session leaders]:session leader:_sequence -s , _pids'
- '*-t+[select processes by attached terminal]:tty:_sequence -s , compadd - /dev/pts/<->(N\:s/\\/dev\\//) /dev/tty*(N\:t)'
+ '*-t+[select processes by attached terminal]:tty:_sequence -s , _ttys -D'
'*-u+[select processes by effective user]:user:_sequence -s , _users'
'*-U+[select processes by real user]:user:_sequence -s , _users'
'-o+[specify output format]:property:_sequence -s , _ps_props -'
@@ -163,8 +163,7 @@ if (( CURRENT > 1 )) && [[ $OSTYPE != solaris* || ( $OSTYPE = linux-gnu && $word
*J) _sequence _jails -0 && return ;;
*[MNW]) _files && return ;;
*t)
- _wanted -C option-t-1 ttys expl tty _sequence -s , \
- compadd - /dev/pts/<->(N\:s/\\/dev\\//) /dev/tty*(N\:t) && return
+ _wanted -C option-t-1 ttys expl tty _sequence -s , _ttys -D && return
;;
*p) _wanted -C option-p-1 processes expl 'process ID' _sequence -s , _pids && return;;
*U) _wanted -C option-U-1 users expl user _sequence -s , _users && return ;;
diff --git a/Completion/Unix/Type/_ttys b/Completion/Unix/Type/_ttys
new file mode 100644
index 0000000..5e55985
--- /dev/null
+++ b/Completion/Unix/Type/_ttys
@@ -0,0 +1,19 @@
+#autoload
+
+# Options:
+#
+# -d strip /dev/ prefix from matches
+# -D matches allowed with or without /dev/ prefix
+
+local -a ttys expl pre
+local stripdev optdev
+
+zparseopts -D -K -E d=stripdev D=optdev
+
+ttys=( /dev/tty?*(N) /dev/pts/^ptmx(N) )
+ttys=( ${ttys#/dev/} )
+[[ -z $stripdev ]] && pre=( -p /dev/ )
+
+_description ttys expl 'tty'
+[[ -n $optdev ]] && compadd "$@" "$expl[@]" -M 'r:|/=* r:|=*' -a ttys && return
+compadd "$@" "$expl[@]" "$pre[@]" -M 'r:|/=* r:|=*' -a ttys
next prev parent reply other threads:[~2015-06-01 22:25 UTC|newest]
Thread overview: 7+ messages / expand[flat|nested] mbox.gz Atom feed top
2015-05-23 10:15 Daniel Shahaf
2015-06-01 22:19 ` Oliver Kiddle [this message]
2015-06-11 12:09 ` bug with hidden prefixes Oliver Kiddle
2015-06-11 15:45 ` Bart Schaefer
2015-06-11 15:53 ` Roman Neuhauser
2015-06-11 16:35 ` Bart Schaefer
2015-06-11 11:24 ` [PATCH] completion: Add FreeBSD's watch(1) Daniel Shahaf
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=18592.1433197179@thecus.kiddle.eu \
--to=okiddle@yahoo.co.uk \
--cc=zsh-workers@zsh.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).