From: Oliver Kiddle <opk@u.genie.co.uk>
To: zsh-workers@sunsite.auc.dk
Subject: PATCH: _zmodload
Date: Fri, 18 Aug 2000 15:43:18 +0100 [thread overview]
Message-ID: <200008181443.PAA95540@cm01.ess> (raw)
In-Reply-To: <200008160923.LAA11449@beta.informatik.hu-berlin.de>
On 16 Aug, Sven wrote:
> Oliver Kiddle wrote:
>
> > On the subject of zmodload completion, how would I prevent the 'module
> > alias' description from being displayed when there are no module
> > aliases
>
> Eh? The description for the aliases should not be displayed when there
> are no matches added for it
That was what I had thought. I've just had a closer look and the problem
was something to do with ${${(f)"$(zmodload -A)"}%% *} returning a
single blank or something when there were no aliases. It's irrelevant
now anyway.
> Anyway. Here is the change to the parameter module to report aliases
> correctly in the $modules parameter. They have values of the form
> `alias:<name>', where <name> is, of course, the aliased-to-name.
>
> No changes to _zmodload. If Oliver is working on the _arguments
> version anyway...
Well here is the _arguments version and I've also tried to make use of
the $modules parameter where possible. Is my strategy of retricting the
arguments to _tags and then completing everything in the while _tags
loop okay? It seems to work and was the easiest way I could find to
handle _zmodload seeing as it has all the flags first.
Shouldn't we maybe have an option to remove module aliases (-u combined
with -A) or have I missed something?
Oliver
--- Completion/Builtins/_zmodload Fri Aug 18 11:26:53 2000
+++ Completion/Builtins/_zmodload Fri Aug 18 16:31:09 2000
@@ -1,21 +1,46 @@
#compdef zmodload
-local fl="$words[2]" expl ret=1
+local suf comp state line expl curcontext="$curcontext" ret=1
+typeset -A opt_args
+suf=()
-if [[ "$fl" = -*(a*u|u*a)* || "$fl" = -*a* && CURRENT -ge 4 ]]; then
- _wanted builtins expl 'builtin command' compadd "$@" -k builtins
-elif [[ "$fl" = -*u* ]]; then
- _wanted modules expl module compadd -k modules
-else
- _tags files aliases
- while _tags; do
- _requested files expl 'module file' \
- _files -W module_path -/g '*.(dll|s[ol])(:r)' && ret=0
- if _requested aliases expl 'module alias'; then
- local array
- array=(${${(f)"$(zmodload -A)"}%% *})
- (( $#array )) && compadd "${expl[@]}" -- $array && ret=0
- fi
- (( ret )) || break
- done
+_arguments -C -A "-*" -s \
+ '(-d -e)-i[suppress error if command would do nothing]' \
+ '-u[unload module]' \
+ '(-i)-d[list or specify module dependencies]' \
+ '(-e)-a[autoload module]' \
+ '(-c -I -p -f)-b[autoload module for builtins]' \
+ '(-b -I -p -f)-c[autoload module for condition codes]' \
+ '(-b -c -p -f)-I[define infix condition names]' \
+ '(-b -c -I -f)-p[autoload module for parameters]' \
+ '(-b -c -I -p)-f[autoload module for math functions]' \
+ '(-i -u -d -a -b -c -p -f -L -A)-e[test if modules are loaded]' \
+ '(-e -u)-L[output in the form of calls to zmodload]' \
+ '(-i -u -d -a -b -c -I -p -f -e)-A[create module aliases]' \
+ '*:params:->params' && ret=0
+
+[[ $state = params ]] || return ret
+
+(( $+opt_args[-A] )) && compset -P '*=' || suf=( -S '=' )
+
+comp=( files aliases )
+if (( $+opt_args[-u] )); then
+ if (( $+opt_args[-b] || $+opt_args[-a] )); then
+ comp=( builtins )
+ else
+ comp=( loadedmodules aliases )
+ fi
fi
+(( $+opt_args[-a] && CURRENT > 3 )) && comp=( builtins )
+
+_tags "$comp[@]"
+while _tags; do
+ _requested builtins expl 'builtin command' \
+ compadd "$@" -k builtins && ret=0
+ _requested loadedmodules expl 'loaded modules' \
+ compadd -k 'modules[(R)loaded]' && ret=0
+ _requested files expl 'module file' \
+ _files -W module_path -/g '*.(dll|s[ol])(:r)' && ret=0
+ _requested aliases expl 'module alias' \
+ compadd "$suf[@]" -k 'modules[(R)alias*]' && ret=0
+done
next prev parent reply other threads:[~2000-08-18 14:48 UTC|newest]
Thread overview: 6+ messages / expand[flat|nested] mbox.gz Atom feed top
2000-08-16 9:23 PATCH: $modules (was: Re: Seg fault with zmodload -u) Sven Wischnowsky
2000-08-16 9:45 ` Peter Stephenson
2000-08-18 14:43 ` Oliver Kiddle [this message]
2000-08-21 6:04 ` PATCH: _zmodload Andrej Borsenkow
2000-08-21 8:00 Sven Wischnowsky
2000-08-21 8:34 ` Andrej Borsenkow
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=200008181443.PAA95540@cm01.ess \
--to=opk@u.genie.co.uk \
--cc=zsh-workers@sunsite.auc.dk \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).