From: Clint Adams <clint@zsh.org>
To: zsh-workers@sunsite.dk
Subject: new prompt theme
Date: Sun, 27 May 2001 01:01:17 -0400 [thread overview]
Message-ID: <20010527010117.A29400@dman.com> (raw)
This prompt is a stripped down modified act-a-like to something that
was probably posted to one of these mailing lists about 4 years ago..
by whom I don't recall.
Index: Functions/Prompts/prompt_clint_setup
===================================================================
RCS file: prompt_clint_setup
diff -N prompt_clint_setup
--- /dev/null Thu May 24 22:33:05 2001
+++ prompt_clint_setup Sat May 26 21:46:51 2001
@@ -0,0 +1,73 @@
+# clint prompt theme
+
+prompt_clint_help () {
+ cat <<'EOF'
+
+ prompt clint [<color1> [<color2> [<color3> [<color4> [<color5>]]]]]
+
+ defaults are red, cyan, green, yellow, and white, respectively.
+
+EOF
+}
+
+prompt_clint_setup () {
+ local -a pcc
+ local -A pc
+ local p_date p_tty p_plat p_ver p_userpwd p_apm p_shlvlhist p_rc p_end
+
+ pcc[1]=${1:-'red'}
+ pcc[2]=${2:-'cyan'}
+ pcc[3]=${3:-'green'}
+ pcc[4]=${4:-'yellow'}
+ pcc[5]=${5:-'white'}
+
+ pc['\[']="%{$fg_no_bold[$pcc[1]]%}["
+ pc['\]']="%{$fg_no_bold[$pcc[1]]%}]"
+ pc['<']="%{$fg_no_bold[$pcc[1]]%}<"
+ pc['>']="%{$fg_no_bold[$pcc[1]]%}>"
+
+ p_date="$pc['\[']%{$fg_no_bold[$pcc[2]]%}%D{%a %y/%m/%d %R %Z}$pc['\]']"
+ p_tty="$pc['\[']%{$fg_no_bold[$pcc[3]]%}%l$pc['\]']"
+ p_plat="$pc['\[']%{$fg_no_bold[$pcc[2]]%}${MACHTYPE}/${OSTYPE}/$(uname -r)$pc['\]']"
+ p_ver="$pc['\[']%{$fg_no_bold[$pcc[2]]%}${ZSH_VERSION}$pc['\]']"
+
+ p_userpwd="$pc['<']%{$fg_no_bold[$pcc[3]]%}%n@%m%{$fg_bold[$pcc[5]]%}:%{$fg_no_bold[$pcc[4]]%}%~$pc['>']"
+ [[ -f /proc/apm ]] && p_apm="%(2v.-%2v-.)"
+
+ p_shlvlhist="%{$reset_color%}zsh%(2L./$SHLVL.) %B%h%b "
+ p_rc="%(?..[%?%v1] )"
+ p_end="%{$reset_color%}%B%#%b %{$fg_no_bold[$pcc[2]]%}"
+
+ POSTEDIT="$reset_color"
+
+ prompt="$p_date$p_tty$p_plat$p_ver
+$p_userpwd
+$p_shlvlhist$p_rc$p_apm$p_end"
+ PS2='%(4_.\.)%3_> %E'
+
+ [[ -f /proc/apm ]] &&
+ precmd () { prompt_clint_precmd ; prompt_clint_apm_precmd } ||
+ precmd () { prompt_clint_precmd }
+ preexec () { }
+}
+
+prompt_clint_precmd () {
+ setopt noxtrace localoptions
+ local exitstatus=$?
+
+ [[ $exitstatus -ge 128 ]] && psvar[1]=" $signals[$exitstatus-127]" ||
+ psvar[1]=""
+
+ [[ -o interactive ]] && jobs -l
+
+}
+
+prompt_clint_apm_precmd () {
+ setopt noxtrace localoptions
+ local bat
+
+ bat=${${="$(</proc/apm)"}[7]/%/%%}
+ [[ $bat == "100%" ]] && psvar[2]=() || psvar[2]=$bat
+}
+
+prompt_clint_setup "$@"
reply other threads:[~2001-05-27 5:01 UTC|newest]
Thread overview: [no followups] expand[flat|nested] mbox.gz Atom feed
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20010527010117.A29400@dman.com \
--to=clint@zsh.org \
--cc=zsh-workers@sunsite.dk \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).