* Acrobat Reader completion plugin
@ 2003-04-25 13:57 Haakon Riiser
0 siblings, 0 replies; only message in thread
From: Haakon Riiser @ 2003-04-25 13:57 UTC (permalink / raw)
To: zsh-workers
[-- Attachment #1: Type: text/plain, Size: 125 bytes --]
I've written a completion plugin for Acrobat Reader 5.0.x.
Feel free to include it with zsh if you like it. :-)
--
Haakon
[-- Attachment #2: _acroread --]
[-- Type: text/plain, Size: 1439 bytes --]
#compdef acroread
# $Date: 2003/04/22 10:31:47 $
local context state line
typeset -A opt_args
local global_opts
global_opts=(
"*:pdf_file_1 [pdf_file_2] ...:_files -g '*.(#i)pdf'"
"-display:host\:display:"
"-geometry:[<width>x<height>][{+|-}<x offset>{+|-}<y offset>]:"
-help
-helpall
\*-iconic
\*+iconic
"-name:application name:"
"*-setenv:<var>=<value>:"
-tempFile
"-tempFileTitle:title:"
"(+useFrontEndProgram)-useFrontEndProgram" "(-useFrontEndProgram)+useFrontEndProgram"
"-visual:or <visual class> [depth=<depth>]:(id= best default)"
"-xrm:X resource specification:"
"-toPostScript:*::PostScript conversion options:= ->tops"
)
local tops_opts
tops_opts=(
"-pairs:*:pdf_file_1 ps_file_1 ...:_files -g '*.(#i)(pdf|ps)'"
-binary
"-start:integer:"
"-end:integer:"
-optimizeForSpeed
-landscape
-reverse
"(-even)-odd"
"(-odd)-even"
-commentsOff
"(-level2 -level3)-level1"
"(-level1 -level3)-level2"
"(-level1 -level2)-level3"
-printerhalftones
-saveVM
"-scale:integer:"
-shrink
"-size:page size (or custom size wxh in points):(letter tabloid ledger legal executive a3 a4 a5 b4 b5)"
"-transQuality:transparency flattening level:(1 2 3 4 5)"
"*:pdf_file ... [ps_dir]:_files -g '*.(#i)pdf'"
)
_arguments $global_opts && return 0
[[ "$state" = tops ]] && _arguments $tops_opts && return 0
return 1
^ permalink raw reply [flat|nested] only message in thread
only message in thread, other threads:[~2003-04-25 13:57 UTC | newest]
Thread overview: (only message) (download: mbox.gz / follow: Atom feed)
-- links below jump to the message on this page --
2003-04-25 13:57 Acrobat Reader completion plugin Haakon Riiser
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).