From: Doug Kearns <djkea2@mugca.its.monash.edu.au>
To: zsh-workers@sunsite.dk
Subject: PATCH: new completion for php
Date: Wed, 14 Apr 2004 14:39:30 +1000 [thread overview]
Message-ID: <20040414043930.GC3830@localhost.localdomain> (raw)
Here's a new completion function for the PHP command line interface.
Regards,
Doug
Index: Completion/Unix/Command/_php
===================================================================
RCS file: Completion/Unix/Command/_php
diff -N Completion/Unix/Command/_php
--- /dev/null 1 Jan 1970 00:00:00 -0000
+++ Completion/Unix/Command/_php 14 Apr 2004 05:42:52 -0000
@@ -0,0 +1,37 @@
+#compdef php
+
+# PHP 4.3.6RC2 (cli) (built: Apr 14 2004 00:14:04)
+
+local curcontext="$curcontext" line state
+typeset -A opt_args
+
+_arguments -S \
+ {-a,--interactive}'[run interactively]' \
+ {-c,--php-ini}'[look for php.ini file in the specified directory]:directory:_files -/' \
+ {-n,--no-php-ini}'[no php.ini file will be used]' \
+ {-d,--define}"[define INI entry]:configuration directive:->ini" \
+ {-e,--profile-info}'[generate extended information for debugger/profiler]' \
+ '(- *)'{-h,--help}'[display help information]' \
+ '(- *)'{-i,--info}'[PHP information]' \
+ '(-)'{-l,--syntax-check}'[syntax check only (lint)]' \
+ '(- *)'{-m,--modules}'[show compiled in modules]' \
+ '(1 -l --syntax-check -s --syntax-highlight -w --strip)'{-r,--run}'[run the specified PHP code without using script tags <?..?>]:PHP code:'\
+ '(-)'{-s,--syntax-highlight}'[display colour syntax highlighted source]' \
+ '(- *)'{-v,--version}'[display version information]' \
+ '(-)'{-w,--strip}'[display source with stripped comments and whitespace]' \
+ {-z,--zend-extension}'[load specified Zend extension]:extension file:_files' \
+ '(-)1:PHP file:_files -g "*.php(-.)"' \
+ '*:script argument:_files' && return
+
+case $state in
+ ini)
+ if compset -P '*='; then
+ _default
+ else
+ _message -e configuration-directives 'configuration directive'
+ fi
+ ;;
+esac
+
+return 1
+
reply other threads:[~2004-04-14 5:45 UTC|newest]
Thread overview: [no followups] expand[flat|nested] mbox.gz Atom feed
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20040414043930.GC3830@localhost.localdomain \
--to=djkea2@mugca.its.monash.edu.au \
--cc=zsh-workers@sunsite.dk \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).