From mboxrd@z Thu Jan  1 00:00:00 1970
Date: Fri, 31 Mar 2006 09:13:39 -0500
From: Clint Adams <clint@zsh.org>
To: zsh-workers@sunsite.dk
Subject: PATCH: _analyseplugin
Message-ID: <20060331141339.GA17854@scowler.net>
MIME-Version: 1.0
Content-Type: text/plain; charset=us-ascii
X-Seq: zsh-workers 22392

Can't commit to CVS since sourceforge is broken right now.

--- /dev/null
+++ mod/Completion/Linux/Command/_analyseplugin
@@ -0,0 +1,25 @@
+#compdef analyseplugin
+
+local expl context state line nopts ret=1
+typeset -A opt_args
+
+_arguments \
+    '-l[Gives a brief listing (one line per plugin)]' \
+    '(-)1:plugin file:->pfile' \
+    '(-)2::plugin label:->plabel' && ret=0
+
+case "$state" in
+    pfile)
+	_wanted plugin-files expl 'plugin file' compadd \
+	    ${~${^${${(f)"$(_call_program ladspa-plugins listplugins 2> /dev/null)"}:#[[:space:]]*}/%:/(:t:r)}} \
+	    && return
+	;;
+    plabel)
+	typeset -a plabel
+	nopts=(${words:#-*})
+	plabel=(${${(f)"$($nopts[1] -l $nopts[2] 2> /dev/null)"}/[[:space:]]##/:})
+	_describe -t plugin-label 'plugin label' plabel && return
+	;;
+esac
+
+return ret