#compdef gnupod_search gnupod_search.pl

# completions for gnupod_search.pl version 0.98.3
# The author calls this script gnupod_search.pl; however Debian
# GNU/Linux strips off the .pl extension

local arguments

arguments=(
    --help'[display help and exit]'
    --version'[display version information and exit]'
    '(-m --mount)'{-m,--mount=}'[iPod mountpoint (default is $IPOD_MOUNTPOINT)]:mount point:_files'
    '(-t --title)'{-t,--title=}'[search songs by title]:title string:'
    '(-a --artist)'{-a,--artist=}'[search songs by artist]:artist string:'
    '(-l --album)'{-l,--album=}'[search songs by album]:album string:'
    '(-i --id)'{-i,--id=}'[search songs by ID]:ID integer:'
    '(-g --genre)'{-g,--genre=}'[search songs by genre]:genre string:'
    '(-c --playcount)'{-c,--playcount=}'[search songs by playcount]:playcount:'
    '(-R --podcastrss)'{-R,--podcastrss=}'[search songs by RSS]:RSS:'
    '(-G --podcastguid)'{-G,--podcastguid=}'[search songs by GUID]:GUID:'
    '(-o --match-once)'{-o,--match-once}'[search does not need to match multiple times]'
    --delete'[remove matched songs from the iPod]'
    --view='[modify output (default is ialt)]:output string:'
    --rename='[rename key into value for matched songs]:KEY=VALUE:'
)

_arguments : $arguments