From: Peter Stephenson <p.stephenson@samsung.com>
To: zsh-workers@zsh.org
Subject: Re: implicit previous command, only state what should change
Date: Tue, 15 Jul 2014 17:58:08 +0100 [thread overview]
Message-ID: <20140715175808.660f4832@pwslap01u.europe.root.pri> (raw)
In-Reply-To: <874myk3ocp.fsf@debian.uxu>
On Mon, 14 Jul 2014 00:06:46 +0200
Emanuel Berg <embe8573@student.uu.se> wrote:
> Let's say I write:
>
> $ grep user-home-directory *.el
>
> After that, I realize that it should have been
> `user-emacs-directory'.
>
> Is there a way to tell zsh to "execute the previous
> command again, only substitute the first argument for
> user-emacs-directory"?
The read-from-minibufer change is a bug fix: NUMERIC was being
propagated down to the first command read within the recursive edit.
I suspect that might be regarded as a bug in recursive-edit.
diff --git a/Doc/Zsh/contrib.yo b/Doc/Zsh/contrib.yo
index 2fcfbbd..4ee404c 100644
--- a/Doc/Zsh/contrib.yo
+++ b/Doc/Zsh/contrib.yo
@@ -2328,6 +2328,31 @@ The name is a slight misnomer, as in fact the shell's own minibuffer is
not used. Hence it is still possible to call tt(executed-named-cmd) and
similar functions while reading a value.
)
+tindex(replace-argument)
+tindex(replace-argument-edit)
+item(tt(replace-argument), tt(replace-argument-edit))
+(
+The function tt(replace-argument) can be used to replace a command
+line argument in the current command line or, if the current command
+line is empty, in the last command line executed (the new command line
+is not executed). Arguments are as delimited by standard shell syntax,
+
+If a numeric argument is given, that specifies the argument to be
+replaced. 0 means the command name, as in history expansion.
+
+If no numeric argument is given, the current argument is replaced;
+this is the last argument if the previous history line is being used.
+
+The function prompts for a replacement argument.
+
+If the widget contains the string tt(edit), for example is defined as
+
+example(zle -N replace-argument-edit replace-argument)
+
+then the function presents the current value of the argument for
+editing, otherwise the editing buffer for the replacement is
+initially empty.
+)
tindex(replace-string)
tindex(replace-string-again)
tindex(replace-pattern)
diff --git a/Functions/Zle/read-from-minibuffer b/Functions/Zle/read-from-minibuffer
index 57e9268..19d1bd5 100644
--- a/Functions/Zle/read-from-minibuffer
+++ b/Functions/Zle/read-from-minibuffer
@@ -39,6 +39,8 @@ local readprompt="$1" lbuf_init="$2" rbuf_init="$3"
read -k $keys
stat=$?
else
+ local NUMERIC
+ unset NUMERIC
zle recursive-edit -K main
stat=$?
(( stat )) || REPLY=$BUFFER
diff --git a/Functions/Zle/replace-argument b/Functions/Zle/replace-argument
new file mode 100644
index 0000000..b43fc39
--- /dev/null
+++ b/Functions/Zle/replace-argument
@@ -0,0 +1,46 @@
+# Replace an argument to a command, delimited by normal shell syntax.
+# Prompts for the replacement.
+# With no numeric argument, replace the current argument.
+# With a numeric argument, replace that argument: 0 = command word,
+# as in history expansion.
+# If editing buffer is empty, use previous history line.
+
+autoload -Uz split-shell-arguments read-from-minibuffer
+
+if (( ${#BUFFER} == 0 )); then
+ (( HISTNO-- ))
+ CURSOR=${#BUFFER}
+fi
+
+local widget=$WIDGET
+integer numeric cursor=CURSOR
+if (( ${+NUMERIC} )); then
+ numeric=$NUMERIC
+else
+ numeric=-1
+fi
+local reply REPLY REPLY2
+integer index
+split-shell-arguments
+
+if (( numeric >= 0 )); then
+ index=$(( 2 + 2*numeric ))
+else
+ index=$((REPLY & ~1 ))
+fi
+
+local edit
+if [[ $widget = *edit* ]]; then
+ edit=$reply[$index]
+fi
+read-from-minibuffer "Replace $reply[$index] with: " $edit || return 1
+
+integer diff=$(( ${#REPLY} - ${#reply[$index]} ))
+reply[$index]=$REPLY
+
+BUFFER=${(j..)reply}
+if (( cursor > REPLY2 )); then
+ (( CURSOR = cursor + diff ))
+else
+ (( CURSOR = REPLY2 ))
+fi
pws
next prev parent reply other threads:[~2014-07-15 17:08 UTC|newest]
Thread overview: 15+ messages / expand[flat|nested] mbox.gz Atom feed top
2014-07-13 22:06 Emanuel Berg
2014-07-13 22:24 ` Frank Terbeck
2014-07-13 22:50 ` Emanuel Berg
2014-07-14 2:08 ` Mikael Magnusson
2014-07-14 13:09 ` Emanuel Berg
2014-07-15 6:46 ` Bart Schaefer
2014-07-15 15:42 ` Emanuel Berg
2014-07-15 16:58 ` Peter Stephenson [this message]
2014-07-16 0:36 ` Emanuel Berg
2014-07-16 13:54 ` Peter Stephenson
2014-07-16 20:45 ` Emanuel Berg
2014-07-16 20:53 ` Bart Schaefer
2014-07-16 21:08 ` Emanuel Berg
2014-07-17 8:17 ` Peter Stephenson
2014-07-17 13:01 ` Emanuel Berg
Reply instructions:
You may reply publicly to this message via plain-text email
using any one of the following methods:
* Save the following mbox file, import it into your mail client,
and reply-to-all from there: mbox
Avoid top-posting and favor interleaved quoting:
https://en.wikipedia.org/wiki/Posting_style#Interleaved_style
* Reply using the --to, --cc, and --in-reply-to
switches of git-send-email(1):
git send-email \
--in-reply-to=20140715175808.660f4832@pwslap01u.europe.root.pri \
--to=p.stephenson@samsung.com \
--cc=zsh-workers@zsh.org \
/path/to/YOUR_REPLY
https://kernel.org/pub/software/scm/git/docs/git-send-email.html
* If your mail client supports setting the In-Reply-To header
via mailto: links, try the mailto: link
Be sure your reply has a Subject: header at the top and a blank line
before the message body.
Code repositories for project(s) associated with this public inbox
https://git.vuxu.org/mirror/zsh/
This is a public inbox, see mirroring instructions
for how to clone and mirror all data and code used for this inbox;
as well as URLs for NNTP newsgroup(s).